Question

<div>    
   <a href="M_TestNamespace_StoredNumber_Swap``1_2_890a5ef1.htm">
         Swap
         <span class="languageSpecificText">
            <span class="cs">&lt;</span>
            <span class="vb">(Of </span><span class="cpp">&lt;</span>
            <span class="fs">&lt;'</span><span class="nu">(</span>
         </span>
         T
         <span class="languageSpecificText">
            <span class="cs">&gt;</span>
            <span class="vb">)</span>
            <span class="cpp">&gt;</span>
            <span class="fs">&gt;</span>
            <span class="nu">)</span>
         </span>
    </a>
<div>

I would like using XSLT and translate above into the result like this:

<div>
   Swap(T)
<div>

FYI, the “(” and “)” are from <span class="nu"/>.

Answer 1

You might want to create a parameter to hold the ‘nu’ value.

<xsl:param name="lang" select="'nu'" />

Then, you would be able to extract the language specific text like so

<xsl:template match="span[@class='languageSpecificText']">
   <xsl:value-of select="span[@class=$lang]" />
</xsl:template>

Here is the full XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html"/>

   <xsl:param name="lang" select="'nu'" />

   <xsl:template match="a">
      <xsl:apply-templates />
   </xsl:template>

   <xsl:template match="span[@class='languageSpecificText']">
      <xsl:value-of select="span[@class=$lang]" />
   </xsl:template>

   <xsl:template match="a/text()">
      <xsl:value-of select="normalize-space()" />
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

When applied to your sample XML, the following is output

<div>Swap(T)</div>

Change the parameter to ‘vb’ and you get the following

<div>Swap(Of T)</div>