Question

Even though I am a relatively precise typist, it is a common error for me to wallop the apostrophe character when I go to hit a carriage return in Vim. This happens especially when I am trying to type :w<CR> or wq<CR>. I end up typing :w'<CR>, or even worse, :wq'<CR>, which gives a couple big red error messages in addition to not doing what I intend. Is there a mapping or some other technique that can be used to overcome this? I can’t imagine why I would ever want to write a file named ', so I am not concerned about blocking that possibility entirely.

Answer 1

You must be careful with using command mappings (and abbreviations), they often fire when they are not supposed to for example during a search or in the middle of a command argument. I typically prefer to use a expression abbreviation.

Put the following in your ~/.vimrc:

cnoreabbrev <expr> w getcmdtype() == ':' && getcmdline() ==# 'w' ? 'w' . EatChar("'") : 'w'
cnoreabbrev <expr> wq getcmdtype() == ':' && getcmdline() ==# 'wq' ? 'wq' . EatChar("'") : 'wq'

function! EatChar(pat)
  let c = nr2char(getchar(0))
  return (c =~ a:pat) ? '' : c
endfunction

This abbreviation uses a function called EatChar which takes a pattern that will be “eaten” or ignored after the abbreviation is expanded. See :helpg Eatchar for an different example of its usage.

The abbreviations will only expand and look to “eat” a quote when all the following criteria is met:

• is in normal ex mode: getcmdtype() == ':'
• at the beginning of the command: getcmdline() ==# 'w'

Otherwise the abbreviation is expanded to the same as the {lhs} i.e. w or wq

Disadvantages to this approach:

• expression abbrevations require vim 7+
• if for whatever reason you really do want to type :w' you will have to type the quote twice , use a space to separate the command form the filename, or type Ctrl+v followed by '
• must create an additional abbreviation for each fat fingering senario

For more information see:

:h abbreviations
:h :map-<expr>
:h getcmdtype(
:h getcmdline(
:helpg Eatchar