Question

First off, here’s my code:

Sub SimulatePortfolio()
    Dim lambda As Double
    Dim num As Integer
    Dim cycles As Long
    Column = 12
    q = 1.5
    lambda = 0.05
    cycles = 100000
    Dim data(1 To 100000, 1 To 10) As Integer
    Dim values(1 To 10) As Double
    For i = 1 To 10
        values(i) = 0
    Next i
    temp = lambda
    For i = 1 To cycles
        lambda = temp
        num = 10
        t = 0
        Dim temps(1 To 10) As Integer
        For k = 1 To 10
            temps(k) = 1000
        Next k
        Do While (t < 10 And num > 0)
            t = t + tsim(lambda, num)
            For j = 1 To 10
                If (j > t) Then
                    temps(j) = temps(j) - 50
                End If
            Next j
            num = num - 1
            If (num <= 0) Then
                Exit Do
            End If
            lambda = lambda * q
        Loop
        For l = 1 To 10
            values(l) = values(l) + temps(l)
            data(i, l) = temps(l)
        Next l
    Next i
    For i = 1 To 10
        Cells(i + 1, Column) = values(i) / cycles
        'Problem occurs on this line:
        Cells(i + 1, Column + 1).Value = Application.WorksheetFunction.Var(Application.WorksheetFunction.Index(data, i, 0))
    Next i
End Sub

Function tsim(lambda As Double, num As Integer) As Double
    Dim v As Double
    Dim min As Double
    Randomize
    min = (-1 / lambda) * Log(Rnd)
    For i = 1 To (num - 1)
        Randomize
        v = (-1 / lambda) * Log(Rnd)
        If (min > v) Then
            min = v
        End If
    Next i
    tsim = min
End Function

When I set the value for cycles to 10000, it runs fine without a hitch. When I go to 100000 cycles, it gets an Error 13 at the indicated line of code.

Answer 1

Having been aware that Application.Tranpose is limited to 65536 rows with variants (throwing the same error) I tested the same issue with Index

It appears that Application.WorksheetFunction.Index also has a limit of 65536 rows when working with variants – but standard ranges are fine

So you will need to either need to dump data to a range and work on the range with Index, or work with two arrays

Sub Test()
Dim Y
Dim Z
'works in xl07/10 
Debug.Print Application.WorksheetFunction.Index(Range("A1:A100000"), 1, 1)
Y = Range("A1:A65536")
`works
Debug.Print Application.WorksheetFunction.Index(Y, 1, 1)
'fails in xl07/10  
Z = Range("A1:A65537")
Debug.Print Application.WorksheetFunction.Index(Z, 1, 1)
End Sub