Question

Firstly, i have a grdData at my main page. After choosing the data i want and went to another page using

    Request.QueryString("id")

In that page i would like to make another grdData using the

    Request.QueryString("id")

but came upon an error by

    Value of type 'cfeedback' cannot be converted to 'system.collections.arraylist'

Below are my codes

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load 
    Dim objArrayList As New ArrayList
    Dim objCDBFeedback As New CDBFeedback
    Dim intGuestID2 As Integer
    intGuestID2 = Request.QueryString("id")
    objArrayList = objCDBFeedback.getFeedBack(intGuestID2)
    grdResult.DataSource = objArrayList


    grdResult.DataBind()

    grdResult.HeaderRow.BackColor = Drawing.Color.AliceBlue
    grdResult.RowStyle.BackColor = Drawing.Color.BlanchedAlmond
    grdResult.AlternatingRowStyle.BackColor = Drawing.Color.LightSalmon

    grdResult.Columns(0).Visible = True


End Sub

My Function

    Public Function getFeedBack(ByVal pintGuestID1 As Integer) As CFeedback
    Dim objCmd As New MySqlCommand
    Dim objCn As New MySqlConnection(connectionString)
    Dim objAdapter As New MySqlDataAdapter
    Dim strSQL As String = ""
    Dim objDs As New DataSet
    Dim objDataRow As DataRow

    strSQL = "SELECT * FROM tblFeedback WHERE strGuestCodeFB=" & pintGuestID1
    objCmd.CommandText = strSQL
    objCmd.Connection = objCn
    objAdapter.SelectCommand = objCmd

    objCn.Open()

    objAdapter.Fill(objDs, "tblFeedback")
    objDataRow = objDs.Tables("tblFeedback").Rows(0)
    Dim objCFeedback As New CFeedback


    objCFeedback.Feedback = objDataRow.Item("strGuestCompanyTI")

    objCn.Close()
    Return objCFeedback
End Function

My Class

Public Class CFeedback
Private strGuestCodeFB As Integer
Private strFeedBackFB As String

Public Property GuestId() As String
    Get
        Return strGuestCodeFB
    End Get
    Set(ByVal value As String)
        strGuestCodeFB = value
    End Set
End Property

Public Property Feedback() As String
    Get
        Return strFeedBackFB
    End Get
    Set(ByVal value As String)
        strFeedBackFB = value
    End Set
End Property

End Class

So is it possible to have a grdData base on querystring?

Answer 1

The very first thing that you need to do is edit your code behind and add the following two lines at the top:

Option Explicit On
Option Strict On

This will show you at least one error: assigning a type of CFeedback to a type of ArrayList.

You will need to determine what the appropriate resolution to this is, but I suspect that you want to return an ArrayList or generic List from GetFeedback instead of just the one item.

So, among other changes, you will want to change pageload to look something like:

Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    Dim objCDBFeedback As New CDBFeedback
    Dim intGuestID2 As Integer
    intGuestID2 = CInt(Request.QueryString("id"))

    Dim cValues As System.Collections.Generic.List(Of CFeedback)

    cValues = objCDBFeedback.getFeedBack(intGuestID2)

    grdResult.DataSource = cValues
    grdResult.DataBind()

    grdResult.HeaderRow.BackColor = Drawing.Color.AliceBlue
    grdResult.RowStyle.BackColor = Drawing.Color.BlanchedAlmond
    grdResult.AlternatingRowStyle.BackColor = Drawing.Color.LightSalmon

    grdResult.Columns(0).Visible = True

    grdResult.Visible = cValues.Count <> 0
End Sub

And the getFeeback method to look something like:

    Public Function getFeedBack(ByVal pintGuestID1 As Integer) As System.Collections.Generic.List(Of CFeedback)
        Dim cValues As New System.Collections.Generic.List(Of CFeedback)

        Using objCn As New MySqlConnection(connectionString)
            Using objCmd As New MySqlCommand
                Dim strSQL As String = ""

                strSQL = "SELECT * FROM tblFeedback WHERE strGuestCodeFB=" & pintGuestID1
                objCmd.CommandText = strSQL
                objCmd.Connection = objCn

                objCn.Open()

                Using oReader As MySqlDataReader = objCmd.ExecuteReader
                    Do While oReader.Read
                        Dim objCFeedback As New CFeedback

                        objCFeedback.Feedback = oReader.Item("strGuestCompanyTI")

                        cValues.Add(objCFeedback)
                    Loop
                End Using

                objCn.Close()
            End Using
        End Using

        Return cValues
    End Function