Question

For an example I need to sort:

?- mergesort([8,1,[4,6,3],2],Sorted).

The outcome should be:

Sorted = [1, 2, 8, [3, 4, 6]]

Unfortunately I’m not sure what to do. I’ve tried to find an answer myself, but didn’t find a solution. Currently the outcome is:

Sorted = [1, 2, 8, [4, 6, 3]]

My code:

mergesort([],[]).
mergesort([A],[A]).
mergesort([A,B|R],S) :-  
   split([A,B|R],L1,L2),
   mergesort(L1,S1),
   mergesort(L2,S2),
   merge(S1,S2,S).

split([],[],[]).
split([A],[A],[]).
split([A,B|R],[A|Ra],[B|Rb]) :-  split(R,Ra,Rb).

merge(A,[],A).
merge([],B,B).
merge([A|Ra],[B|Rb],[A|M]) :-  A @=< B, merge(Ra,[B|Rb],M).
merge([A|Ra],[B|Rb],[B|M]) :-  A @> B,  merge([A|Ra],Rb,M).

Big thanks in advance!

Answer 1

I would write a simple preprocessing step:

sortl([H|T],[Hs|Ts]) :-
    (   is_list(H)
    ->  mergesort(H,Gs),
        sortl(Gs,Hs)
    ;   Hs = H
    ),
    sortl(T,Ts).
sortl([],[]).

then you could use it this way

?- sortl([8,1,[4,6,[3,4],[1,8],3],2,[1,3,2]],T),mergesort(T,Sorted).
T = [8, 1, [3, 4, 6, [1, 8], [3|...]], 2, [1, 2, 3]],
Sorted = [1, 2, 8, [1, 2, 3], [3, 4, 6, [...|...]|...]]