Question

For my current assignment I need to make an extension for Adobe InDesign using Adobe Creative Suit Extension Builder and Flash Builder. I guess this is more of a question for ones that know Extension Builder and InDesign API.

The point of this extension is to load some data and send some data to a server. I need to make a screenshot of a page, then send it in jpg to a server. But, there are no (or at least i couldnt find any) ways to create a bitmap(to cast it on a object seems impossible, because this Objects are just Objects, and not DisplayObjects).

I managed to silently export pages as jpegs, now I’m thinking about loading them and sending but that will require building an AIR app to handle it all, so this will be a bit bulky.

So to sum up the question, how to take a screencapture of all elements on a page in InDesign using CS Ext.Builder?

Answer 1

what is the problem with export to JPG ? You can choose to export the page or the objects themselves.

Here is a snippet I wrote in a recent project. Hope it helps.

public static function getFilePath():String {

var app:com.adobe.indesign.Application = InDesign.app;
var sel:* = app.selection, oldResolution:Number, oldColorSpace:JpegColorSpaceEnum, groupItems:Array = [], i:int = 0, n:int = sel.length;

if (!sel || !n )
        {
            Alert.show("Pas de selection !", "title", Alert.OK, Sprite(mx.core.Application.application));
            return "";
        }

        for ( i = 0 ; i < n ; i ++ )
        {
            groupItems [ groupItems.length ] = sel[i];
        }
        sel = ( sel.length > 1 )? app.activeDocument.groups.add ( sel ) : sel[0] ;

        var tempFolder:File = File.createTempDirectory();
        AppModel.getInstance().jpgFolder = tempFolder;
        var jpgFile:File = new File ();
        jpgFile.nativePath = tempFolder.nativePath + "/temp.jpg";

        oldResolution = app.jpegExportPreferences.exportResolution;
        app.jpegExportPreferences.exportResolution = 72;
        oldColorSpace = app.jpegExportPreferences.jpegColorSpace;
        app.jpegExportPreferences.jpegColorSpace = JpegColorSpaceEnum.GRAY;
        sel.exportFile ( ExportFormat.jpg, jpgFile );


        app.jpegExportPreferences.jpegColorSpace = oldColorSpace;
        app.jpegExportPreferences.exportResolution = oldResolution;

        if ( sel is Group )
        {
            sel.ungroup();
            app.select ( groupItems );
        }

        return jpgFile.nativePath;
    }