Question

For my lookup tables, the ones that are the same for every user in the application, I do an

Application.objectname = createobject(...).init(datasource)

in the init method, I read the table into the this scope like so:

cfquery name="this.queryname"
return this

Now, whenever I need to reference the query, I can refer to it like this:

cfselect query="Application.objectname.queryname" ...

Q: Is there anything wrong with that?

Answer 1

No, that would be fine. The server will keep the entire object instance in memory as part of the application scope, which will include all of its properties.

As a question of style, I would suggest making your query a private property (in the variables scope in a CFC) rather than a public one (in a CFC’s this scope). Allowing an object property to be public implies that as the black box designer, you’re okay with an unknown developer overwriting the value. If these are database lookup tables you’re storing, I’m guessing you intend this data to be read-only. Consider the following:

<cfcomponent hint="Proxy for database lookup tables" output="false">
    <cfproperty name="variables.lookupTable1" type="query" hint="[Private] lookupTable1 query object." />
    <cfproperty name="variables.lookupTable2" type="query" hint="[Private] lookupTable2 query object." />
    <!--- Implicit initialization --->
    <cfscript>
        variables.lookupTable1 = QueryNew('');
        variables.lookupTable2 = QueryNew('');
    </cfscript>

    <!--- Active initialization --->
    <cffunction name="init" returntype="void" access="public" hint="Initializes the query objects with data." output="false">
        <cfargument name="dsn" type="string" required="true" hint="The datasource to use." />
        <cfquery name="variables.lookupTable1" datasource="#arguments.dsn#">
            SELECT * FROM [TblFoo]
        </cfquery>
        <cfquery name="variables.lookupTable2" datasource="#arguments.dsn#">
            SELECT * FROM [TblBar]
        </cfquery>
    </cffunction>

    <!--- Data Fetching Methods --->
    <cffunction name="getFoo" returntype="query" access="public" hint="Returns the contents of TblFoo." output="false">
        <cfreturn variables.lookupTable1 />
    </cffunction>

    <cffunction name="getBar" returntype="query" access="public" hint="Returns the contents of TblFoo." output="false">
        <cfreturn variables.lookupTable2 />
    </cffunction>
</cfcomponent>