Question

Given a matrix with 25 rows and 80 columns but with the attributes its 160 columns
I have to write a program in assembly to move a four letter string “Fool” (say) to move across the matrix back and forth.

What I have done till now:

mov bx,0B800H
mov ds, bx
mov si, 1760

mov cx,80
FOOL: add si,-6
mov [si], " "
add si, 2
mov [si], "F"
add si, 2
mov [si], "O"
add si, 2
mov [si], "O"
add si,2
mov [si],"L"
loop FOOL

mov cx, 80
FOOOL: add si,-6

mov [si], "F"
add si, -2
mov [si], "O"
add si, 2
mov [si], "O"
add si,2
mov [si],"L"
add si,2 
mov [si], " "
loop FOOOL

mov ah,9
int 21H

But with this code, when its reversed, the last letter comes before the first. I am a newbie in assembly, I have tried 8085 before but this is my first attempt to 8086.

I would be grateful if somebody help me to fix this problem.

Answer 1

This works:

; compile with nasm:
; nasm.exe fool.asm -f bin -o fool.com
bits 16
org 100h

mov bx,0B800H
mov ds, bx
mov si, 80*11*2 ; 1760

mov cx, 80+1-5
FOOL:
mov [si], byte " "
add si, 2
mov [si], byte "F"
add si, 2
mov [si], byte "O"
add si, 2
mov [si], byte "O"
add si, 2
mov [si], byte "L"
sub si, 3*2
call delay
loop FOOL

sub si, 1*2

mov cx, 80+1-5
FOOOL:
mov [si], byte "F"
add si, 2
mov [si], byte "O"
add si, 2
mov [si], byte "O"
add si, 2
mov [si], byte "L"
add si, 2 
mov [si], byte " "
sub si, 5*2
call delay
loop FOOOL

mov ax, 4c00h
int 21h

delay:
pusha
push ds

mov ax, 0
mov ds, ax
mov bx, [46ch]

d0:
mov ax, [46ch]
cmp ax, bx
je d0 ; wait for another timer tick (once in ~55 ms)

pop ds
popa
ret