Question

Given an object of type clsPerson:

dim oP as New clsPerson
oP.FirstName = "Sam"

is there a way to interrogate variable oP and a create a new object of that type?

Answer 1

If the class is properly registered with COM (that is, coming from an ActiveX dll project), then yes:

Option Explicit

Private Type Guid
  Data1 As Long
  Data2 As Integer
  Data3 As Integer
  Data4(0 To 7) As Byte
End Type

Private Const CLSCTX_INPROC_SERVER As Long = 1
Private Const IID_IUnknown As String = "{00000000-0000-0000-C000-000000000046}"

Private Declare Function CLSIDFromString Lib "ole32.dll" (ByVal lpsz As Long, ByRef pclsid As Guid) As Long
Private Declare Function IIDFromString Lib "ole32.dll" (ByVal lpsz As Long, ByRef lpiid As Guid) As Long
Private Declare Function CoCreateInstance Lib "ole32.dll" (ByRef rclsid As Guid, ByVal pUnkOuter As Long, ByVal dwClsContext As Long, ByRef riid As Guid, ByRef ppv As Object) As Long



Public Function GetAnotherInstanceOf(ByVal this As Object) As Object
  Static iunk As Guid
  If iunk.Data4(7) = 0 Then
    IIDFromString StrPtr(IID_IUnknown), iunk
  End If

  Dim ti As TLI.TypeInfo

  With New TLI.TLIApplication
    Set ti = .ClassInfoFromObject(this)
  End With

  Dim clsid As Guid
  CLSIDFromString StrPtr(ti.Guid), clsid

  CoCreateInstance clsid, 0, CLSCTX_INPROC_SERVER, iunk, GetAnotherInstanceOf
End Function

Usage:

Dim s As New MSXML2.DOMDocument60

Dim clone As Object

MsgBox TypeName(clone)
Set clone = GetAnotherInstanceOf(s)
MsgBox TypeName(clone)

The TLI is TypeLib Information found in Project -> References.