Question

Given pairs of coordinates

data = {{1, 0}, {2, 0}, {3, 1}, {4, 2}, {5, 1}, 
        {6, 2}, {7, 3}, {8, 4}, {9, 3}, {10, 2}}

I’d like to extract peaks and valleys, thus:

{{4, 2}, {5, 1}, {8, 4}}

My current solution is this clumsiness:

Cases[
 Partition[data, 3, 1],
 {{ta_, a_}, {tb_, b_}, {tc_, c_}} /; Or[a < b > c, a > b < c] :> {tb, b}
]

which you can see starts out by tripling the size of the data set using Partition. I think it’s possible to use Cases and PatternSequence to extract this information, but this attempt doesn’t work:

Cases[
 data,
 ({___, PatternSequence[{_, a_}, {t_, b_}, {_, c_}], ___} 
         /; Or[a < b > c, a > b < c]) :> {t, b}
]

That yields {}.

I don’t think anything is wrong with the pattern because it works with ReplaceAll:

data /. ({___, PatternSequence[{_, a_}, {t_, b_}, {_, c_}], ___} 
             /; Or[a < b > c, a > b < c]) :> {t, b}

That gives the correct first peak, {4, 2}. What’s going on here?

Answer 1

One of the reasons why your failed attempt doesn’t work is that Cases by default looks for matches on level 1 of your expression. Since your looking for matches on level 0 you would need to do something like

Cases[
 data,
 {___, {_, a_}, {t_, b_}, {_, c_}, ___} /; Or[a < b > c, a > b < c] :> {t, b}, 
 {0}
]

However, this only returns {4,2} as a solution so it’s still not what you’re looking for.
To find all matches without partitioning you could do something like

ReplaceList[data, ({___, {_, a_}, {t_, b_}, {_, c_}, ___} /; 
    Or[a < b > c, a > b < c]) :> {t, b}]

which returns

{{4, 2}, {5, 1}, {8, 4}}