Question

good afternoon,
I have a problem with the rollback … Treger initially was using to call the procedure and the procedure is triggered rollback but it is …
Now I’m trying to do the rollback from trigger nor …

attached the code and the error

Thanks for your help

USE [Desarrollo_Pruebas]
GO
/****** Object:  Trigger [dbo].[Prueba_tre]    Script Date: 10/30/2012 17:02:53 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

ALTER TRIGGER [dbo].[Prueba_tre] 
   ON  [dbo].[Cliente]
    FOR INSERT
AS 
BEGIN

 SET NOCOUNT ON;

begin try
    BEGIN TRAN t1
    SAVE TRAN t1
    INSERT INTO Articulo (Articulo_Codigo, Articulo_Descripcion, Valor_unitario, Categoria_id, msg) VALUES (1040,'EURECA',15000,5,'')
    COMMIT 
    --raiserror ('Test error',16,1)
end try

begin catch
    ROLLBACK TRAN t1
    SELECT    ERROR_NUMBER() AS ERROR_NUMBER, ERROR_MESSAGE() AS ERROR_MESSAGE;
end catch

--SET NOCOUNT ON;
--exec Prueba CLIENTE_ID;

END

Msg 3931, Level 16, State 1, Procedure Prueba_tre, Line 21
The current transaction cannot be committed and cannot be rolled back to a savepoint. Roll back the entire transaction.

THE TABLE IS

the idea is that when I insert into customers products with an insert update ..
at the end of this transaction need to return from the console

CREATE TABLE Articulo
(
   Articulo_Codigo int not null primary key
   , Articulo_Descripcion varchar (100)
   , Valor_unitario int
   , Categoria_Id int not null constraint fk_Categoria references Categoria (CATEGORIA_ID)
)

CREATE TABLE Cliente
(
   CLIENTE_ID int not null primary key
   , CLIENTE_PRIMER_NOMBRE varchar(50)
   , CLIENTE_SEGUNDO_NOMBRE varchar(50)
   , CLIENTE_PRIMER_APELLI varchar(50)
   , CLIENTE_SEGUNDO_APELLI varchar(50)
   , CLIENTE_DIRECCION varchar(90)
   , CLIENTE_TELEFONO int
   , CLIENTE_CIUDAD varchar(50)
)

Answer 1

Сontinue using procedure. I think you just don’t check Exception handling and nested transactions.

CREATE PROCEDURE [dbo].[Prueba_tre]
AS
BEGIN
  SET NOCOUNT ON;
  declare @trancount int;
  set @trancount = @@trancount;
  begin try
    if @trancount = 0
      begin transaction
    else
      save transaction t1

    INSERT INTO Articulo (Articulo_Codigo, Articulo_Descripcion, Valor_unitario, Categoria_id, msg) VALUES (1040,'EURECA',15000,5,'')
    if @trancount = 0 
      commit; 
  end try
  begin catch
    declare @error int, @message varchar(4000 ), @xstate int;
    select @error = ERROR_NUMBER(),
    @message = ERROR_MESSAGE(),
    @xstate = XACT_STATE();
   if @xstate = -1
     rollback;
   if @xstate = 1 and @trancount = 0
     rollback
   if @xstate = 1 and @trancount > 0
     rollback transaction t1
   raiserror ('t1: %d: %s' , 16, 1, @error, @message)
  end catch
END