Question

Guys I’m looking for a simple Excel macro that can copy a row from one sheet to another when a column is different, but in the new sheet is not placed in the same row where they was, else that it will be added contiguously…

Sheet1:

A B C
One Spain 1000
Two Japan 2000
Three EEUU 3000

Sheet2:

A B C
One Italy 1000
Two Japan 2000
Three EEUU 4000

Sheet3(Final):

A B C
One Italy 1000
Three EEUU 4000

I would compare the sheet “Sheet1” with sheet “Sheet2” and if you find any difference in any column, copy the entire row of the worksheet “Sheet2” to a worksheet “Sheet3”.

Any tips would be much obliged.
Sory for my English, but I’m from Argentina.

thanks, Ignacio G

EDIT:
Actually, I’m using this code:

Public Sub ReconReport()
Dim rngCell As Range

For Each rngCell In Worksheets("Sheet1").UsedRange
    If Not rngCell = Worksheets("Sheet2").Cells(rngCell.Row, rngCell.Column) Then _
        Let Worksheets("Sheet3").Cells(rngCell.Row, rngCell.Column) = rngCell
    Next
End Sub

But it just copy different cells, and what I need is that I copy the entire row …

Answer 1

Slow Answer:

Sub ReconReport()
    'Set Worksheets to Variables
    Dim sheetOne, sheetTwo, sheetThree As Worksheet
    Set sheetOne = Worksheets("Sheet1")
    Set sheetTwo = Worksheets("Sheet2")
    Set sheetThree = Worksheets("Sheet3")

    'Find Used Rows and Columns
    Dim usedRows, usedCols As Integer
    usedRows = sheetOne.UsedRange.Rows.Count
    usedCols = sheetOne.UsedRange.Columns.Count

    Dim row, col, copyRow, copyCol As Integer
    copyRow = 1 'Row on sheet three
    For row = 1 To usedRows
        For col = 1 To usedCols
            If Trim(sheetOne.Cells(row, col).Value) <> Trim(sheetTwo.Cells(row, col).Value) Then

                'Copy All Columns from that row (on Sheet2) to Sheet3
                For copyCol = 1 To usedCols
                    sheetThree.Cells(copyRow, copyCol).Value = sheetTwo.Cells(row, copyCol).Value
                Next copyCol

                'Increment the sheet3 row so next info starts on new line
                copyRow = copyRow + 1 

                'Exit column search loop so only one row added if two columns have differences in the same row 
                Exit For

            End If
        Next col
    Next row
End Sub