Question

Has anyone seen a script for checking a user’s add-ins for PowerPivot and giving the user the dialog to install?

Answer 1

Unfortunately PowerPivot doesn’t seem to be listed in the VBA-accessible list of installed add-ins.

Maybe you would like to try this:

Sub installPowerPivot()
If Not isPowerPivotInstalled Then
    MsgBox "PowerPivot is not installed on this machine." & vbCrLf & vbCrLf & _
        "Please visit this website to download the PowerPivot add-in:" & vbCrLf & _
        "http://powerpivot.com"
End If
End Sub


Function isPowerPivotInstalled() As Boolean
Const checkFile As String = "\Microsoft Analysis Services\AS Excel Client\10\Microsoft.AnalysisServices.Modeler.FieldList.dll"
Dim tempFSO As Object
Set tempFSO = CreateObject("Scripting.FileSystemObject")

'check x86 program files folder
If tempFSO.fileexists(Environ("ProgramFiles(x86)") & checkFile) Then
    isPowerPivotInstalled = True
    Exit Function
End If

'if it's a 64bit machine also check the 64bit program files folder
If LCase(Environ("processor_architecture")) = "amd64" Then
    If tempFSO.fileexists(Environ("ProgramW6432") & checkFile) Then
        isPowerPivotInstalled = True
        Exit Function
    End If
End If

'if both checks fail -> false
isPowerPivotInstalled = False
End Function