Question

hello i am trying to load a list of filenames from a folder into a Stringlist. I only want to add the names of files that end in .jpg When i run it now i get access violation errors. Here is what i got.

Selects directory.

procedure TMainForm.Load1Click(Sender: TObject);
var
  DirName: string;
begin
    mylist.Free;
    myList := TList<TBitmap>.Create;
  DirName := 'c:\';
  if SelectDirectory(DirName,[sdAllowCreate, sdPerformCreate, sdPrompt],SELDIRHELP)
  then;
    LoadImages(DirName);
end;

Gets number of totalfiles in folder

function GetFilesCount(Dir : string; Mask : string) : integer;
var
  Path : string;
begin
  Result := 0;
  for Path in TDirectory.GetFiles(Dir, Mask) do
    inc(Result);
end;

Gets filenames from folder

function TMainForm.GetFilenames(Path: string ):TStrings;
var
  Dest: TStrings;
  SR: TSearchRec;
begin
  Dest.create;
  if FindFirst(Path+'*.*', faAnyFile, SR) = 0 then
  repeat
    Dest.Add(SR.Name);
  until FindNext(SR) <> 0;
  FindClose(SR);
  Result := Dest;
  Dest.Free;
end;

and the load iamges

    procedure TMainForm.LoadImages(const Dir: string);
    const
      FIRST_IMAGE = 0;
    var
      iFile : Integer;
      CurFileName: string;
      FoundFile : boolean;
      FileNameTemplate : string;
      FileNames : Tstrings;
    begin
       FileNames.Create;
       FileNameTemplate := IncludeTrailingPathDelimiter(Dir) + '*.jpg';          FileNames:=GetFileNames(FileNameTemplate);                                                 
      try
        ifile := 0;                                                                 
        repeat
          CurFileName := FileNames.Names[ifile];                                      
          showmessage(Curfilename);
 if FoundFile then
      begin
        end;
        Inc(iFile);
      end;
    until not FoundFile;
end;

Answer 1

The problem is here (where you actually have two problems) – actually, you have the same problems twice in your code:

Dest.Create;  // In GetFileNames

FileNames.Create; // In LoadImages

First, TStrings is an abstract class. You can’t create an instance of it; it’s the basis for other more concrete classes like TStringList. Create one of those concrete classes instead.

Second, you have to create the TStringList and store a reference to it.

FileNames := TStringList.Create;

The better way to do it is to create your stringlist and pass it into the function or procedure, since you need the results when it returns. I’ll take a quick pass at one of them for you:

function TMainForm.GetFilenames(const Path: string; const FileList: TStringList ): Boolean;
var
  SR: TSearchRec;
begin
  Assert(Assigned(FileList));      // Make sure it was created and passed in
  FileList.Clear;                  // Remove any previous names
  if FindFirst(Path+'*.*', faAnyFile, SR) = 0 then
  repeat
    FileList.Add(SR.Name);
  until FindNext(SR) <> 0;
  FindClose(SR);
  Result := FileList.Count > 0;  // Return true if we have found any files
end;

Call it like this:

FileNames := TStringList.Create;
try
  if GetFileNames(PathToFolder, FileNames) then
  begin
    // Process files here
    for i := 0 to FileNames.Count - 1 do
    begin
      CurrFile := FileNames[i];
      // Use the file here from CurrFile
    end;

  end;
finally
  FileNames.Free;
end;