Question

Hello I have recently created a C program for my UNI Computing course that generates a web server at localhost:2020 and sends a bmp file of the Mandelbrot set. If you dont know what that is dont worry, its the url part thats important.
The URL is formatted as follows

http://X_(x coordinate)_(y coordinate)_(Zoom Level).bmp

so
http://localhost:2020/X_-0.15_1.03_56.bmp

returns

x: -0.15
y: 1.03
zoom: 56

My goal here is to have an automated process that can take in an x,y position (in the code is fine) and repetitively load the image from the server, each time with a zoom level increased by .01 and save it to either a folder or preferably load them all into a file to be presented as a video.
Im well aware that this would be easier to do in C and just have it save to the file but my goal is to familiarise myself with applescript/automator or a similar program with tasks like this.
Its designed to be a fun learning experience for myself and I will really appreciate any help I can get thank you.

Answer 1

Something like this may work for part of your task. We are downloading all of the images (at each zoom level) using the unix command line utility “curl”. Each image is saved with the name from the url to a folder that you choose. We put this code inside a repeat loop so we can increment the zoom level.

The script shows lots of stuff, particularly how to insert variables directly into an applescript (e.g. hard-coded) and how to get input from the user. It also shows how to run command line utilities from within an applescript (e.g. curl).

So this script should get you started. See if it helps.

-- hard-coded variables
set minZoomLevel to 0
set maxZoomLevel to 10
set zoomIncrement to 0.1

-- get user input variables
set outputFolder to choose folder with prompt "Pick the output folder for the images"
set xDialog to display dialog "Enter the X coordinate" default answer ""
set yDialog to display dialog "Enter the Y coordinate" default answer ""

set posixStyleOutputFolder to POSIX path of outputFolder
set x to text returned of xDialog
set y to text returned of yDialog

set i to minZoomLevel
repeat while i is less than or equal to maxZoomLevel
    set fileName to "X_" & x & "_" & y & "_" & (i as text) & ".bmp"
    set theURL to "http://localhost:2020/" & fileName
    do shell script "curl " & theURL & " -o " & quoted form of (posixStyleOutputFolder & fileName)
    set i to i + zoomIncrement
end repeat