Question

Hello i need to sperate datas with comma and add new data.

<fields>
<field name="example"><value>example,i,am,new,to,xslt</value></field>
<fields>

i need to transform this xml to

<fields>
<field name="example"><value>example</value><value>i</value>am</value><value>new</value><value>to</value><value>xslt</value></field>
<fields>

can any one explain how can i do that using XSLT

Answer 1

I. XSLT 2.0 solution:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="value">
   <xsl:for-each select="tokenize(., ',')">
     <value><xsl:value-of select="."/></value>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the provided XML document (Corrected!!!! for well-formedness):

<fields>
    <field name="example">
        <value>example,i,am,new,to,xslt</value>
    </field>
</fields>

the wanted, correct result is produced:

<fields>
   <field name="example">
      <value>example</value>
      <value>i</value>
      <value>am</value>
      <value>new</value>
      <value>to</value>
      <value>xslt</value>
   </field>
</fields>

---

II. XSLT 1.0 solution:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="value" name="tokenize">
  <xsl:param name="pText" select="."/>

  <xsl:if test="string($pText)">
   <value>
    <xsl:value-of select=
     "substring-before(concat($pText, ','), ',')"/>
   </value>

   <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
        "substring-after($pText, ',')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

when this transformation is applied on the same XML document (above), the same correct result is produced:

<fields>
   <field name="example">
      <value>example</value>
      <value>i</value>
      <value>am</value>
      <value>new</value>
      <value>to</value>
      <value>xslt</value>
   </field>
</fields>

Explanation:

1. Use of the identity rule to copy everything “as-is”.

2. Overriding (of the identity template) template that matches value.

3. In Solution I — appropriate use of the standard XPath 2.0 function tokenize().

4. In Solution II — implementing something loke the tokenize() function using a named template — because there is no tokenize() defined in XPath 1.0/XSLT 1.0.

5. In Solution II for convenience we have merged the template matching value with the named template that performs comma-tokenization.