Question

Hello is there anyone who knows how to convert the following t-sql stored procedure into pl/sql:

ALTER FUNCTION [dbo].[AverageAndTall]()
    RETURNS @Players TABLE
    (
        Number INT,
        Name VARCHAR(20),
        Surname VARCHAR(40),
        Height float,
        Position VARCHAR(40),
        FuzzinessLevel float(3)
    )
AS
BEGIN
    DECLARE  @FuzzyLevel float
    INSERT   @Players (Number, Name, Surname, Height, Position, FuzzinessLevel)
    SELECT   Number, Name, Surname, Height, Position, dbo.MembershipLevel_AverageAndTall(Height) 
    FROM     FuzzyFootballTeam       
    RETURN
END

Thanks for any hints !

Answer 1

You have a table-valued user-defined function. One way to convert this to PL/SQL is to use a function returning a REF CURSOR. Since some type definitions are involved, you better put it into a package:

CREATE OR REPLACE PACKAGE FootballTeam
IS

  TYPE AverageAndTallResult IS RECORD (
    NMBR INT,
    NAME VARCHAR2(20),
    SURNAME VARCHAR2(40),
    HEIGHT NUMBER,
    POSITION VARCHAR2(40),
    FUZZINESS_LEVEL NUMBER );

  TYPE AverageAndTallCursor IS REF CURSOR RETURN AverageAndTallResult;

  FUNCTION AverageAndTall
    RETURN AverageAndTallCursor;

END FootballTeam;
/

CREATE OR REPLACE PACKAGE BODY FootballTeam
IS

  FUNCTION AverageAndTall
    RETURN AverageAndTallCursor
  IS

    l_cursor AverageAndTallCursor;

  BEGIN

    OPEN l_cursor FOR
    SELECT  Number, Name, Surname, Height, Position, MembershipLevel_AverageAndTall(Height) 
    FROM    FuzzyFootballTeam;

    RETURN l_cursor;

  END AverageAndTall;

END FootballTeam;
/