Question

Here is a simplified version of the code I’m working on.

main :: IO ()
main = do
     args <- getArgs
     if null args
       then putStr "> " ; userInput <- getLine
       else userInput <- readFile $ head args

     let conclusion = userInput

This won’t work without do notation, the variable won’t pass to conclusion below when I do use it, and the putStr, which I’m trying to use to create a kind of prompt, just makes it mad.

Is there something that I’m forgetting to add somewhere?

Answer 1

There are a few problems here. First, you need to include do after then and else:

if null args
  then do putStr "> " ; userInput <- getLine
  else do userInput <- readFile $ head args

if in do notation is the same as if everywhere else; you have to put an expression after then and else, not statements, and you need do to turn a bunch of statements into an expression. This still isn’t quite valid, though; the last statement in a do block must be an expression, but you have a bind here. After all, every statement has to have a result value, but a bind has none.

The second problem is, as you’ve observed, that this introduces a new scope, and so you can’t access variables you bind from outside. This makes sense if you think about it; after all, you could bind the variable on one side and not the other. The solution is to simply move the bind outside the if:

main :: IO ()
main = do
     args <- getArgs
     userInput <- if null args
       then do putStr "> " ; getLine
       else readFile $ head args

     let conclusion = userInput

So, the action whose result we bind to userInput is still computed depending on the result of null args, but we bind the variable outside the conditional.

Note that I didn’t add a do to the else branch this time; it’s not required, since there’s only a single expression there. (It’s still valid, but it’s unidiomatic to use do when it’s not necessary.)

This code still won’t work unless you put something after the let conclusion = userInput line (since, like I said, do blocks must end with an expression), but presumably you already have code there.

As an additional note, you should avoid using functions like head and tail; head is a partial function (not defined for every argument — head [] will produce an error), and those are generally considered unidiomatic. You should use pattern-matching instead, like this:

userInput <- case args of
  [] -> do putStr "> " ; getLine
  fileName:_ -> readFile fileName

This is just like the pattern-matching used when defining a function, but for a single value rather than any number of arguments.