Question

Here is what I am trying to achieve (in a .Net 4 WPF client):

1. User types some text in a text box
2. After half a second of no more typing, text is sent asynchronously sent to a server for validation
3. Validation result is shown to the user (this is just text bound to a text block)
4. If the user types more text while the validation is in progress (this takes a couple of seconds) the results from server are ignored and a new validation request is sent instead

From what I have read reactive extensions are a good fit for this but I’m having trouble, in particular step 4.

Secondly I am using mvvm, so how do I put this logic in the view model while subscribing to TextBox.TextChanged in the view.

Answer 1

A few operators come in quite handy here (notably, Throttle for 2 and Switch for 4). Your view model will look something like:

Class ViewModel
    Implements INotifyPropertyChanged
    Implements IDisposable 'to clean up subscription

    Public Sub New()
        _subscription = Observable.FromEventPattern(Of PropertyChangedEventHandler, PropertyChangedEventArgs)(
                            Sub(h) AddHandler Me.PropertyChanged, h,
                            Sub(h) RemoveHandler Me.PropertyChanged, h) _
                        .Where(Function(ep) String.Equals(ep.EventArgs.PropertyName, "Input", StringComparison.Ordinal)) _
                        .Throttle(TimeSpan.FromSeconds(0.5)) _
                        .Select(Function(ep) Validate(Me.Input)) _
                        .Switch() _
                        .ObserveOnDispatcher() _
                        .Subscribe(Sub(v) Me.Output = v)
    End Sub

    Private ReadOnly _subscription As IDisposable

    'put in actual code to notify on change
    Public Property Input As String
    Public Property Output As ValidationResult

    Private Function Validate(toValidate As String) As IObservable(Of ValidationResult)
        'start validation
    End Function

    Public Event PropertyChanged(sender As Object, e As PropertyChangedEventArgs) Implements INotifyPropertyChanged.PropertyChanged
End Class

From the view, bind the text box to Input and set the binding mode to PropertyChanged (instead of the default LostFocus). The result block can then bind to Output.