Question

Here’s one of those ColdFusion things that seems like it should be so easy… but I’m not finding the easy path.

I have an array of lists.
The array could be any size, and the length of each list can be any size.
(this can be manipulated into a multi-dimensional array, whatever… the point is, i have a list of lists)

For example

1. 129,128,127

2. 130,131,132

3. 135,133,134

4. 137,138,136

5. 140,139

6. 141,142

Or a short version… it can vary

1. 13,14,15

2. 11,12

What I need is an array, query or some other data structure
containing all the possible unique combinations, taking one from each list in order … so for the short version, there would be 6 unique combinations. For the first longer example, we would have 3*3*3*3*2*2 = 324 unique combinations.

Counting them is easy… but what’s the best way get the actual combinations in a structured format?
Must be missing something simple… I’ve been very close for hours now!
:-/

Answer 1

Here’s my take.
Credit goes to the php function in this post on codingforums.com: http://www.codingforums.com/showpost.php?p=945289&postcount=3
I just figured how to re-write it in cfml.

<cfscript>
public array function array_cartesian_product(_arrays=[]) {
    var result = [];
    var _arrayslen = arraylen(arguments._arrays);
    var _size = (_arrayslen) ? 1 : 0;
    var _array = '';
    var x = 0;
    var i = 0;
    var j = 0;
    var _current = [];

    for (x=1; x lte _arrayslen; x++) {
        _size = _size * arraylen(arguments._arrays[x]);
        _current[x] = 1;
    }

    for (i=1; i lte _size; i++) {
        result[i] = [];

        for (j=1; j lte _arrayslen; j++) {
            arrayappend(result[i], arguments._arrays[j][_current[j]]);
        }

        for (j=_arrayslen; j gt 0; j--) {
            if (arraylen(arguments._arrays[j]) gt _current[j])  {
                _current[j]++;
                break;
            }
            else {
                _current[j] = 1;
            }
        }

    }

    return result;
}
</cfscript>
<cfset arrays = [[129,128,127],[130,131,132],[135,133,134],[137,138,136],[140,139],[141,142]]>
<cfset r = array_cartesian_product(arrays)>
<cfoutput>#arraylen(r)#</cfoutput>
<cfdump var="#r#">