Question

Hi I was trying to find the DVD drive on computer with the script below. GetDriveType always returning 1, Even I pass the drive letter manually it still returns 1, can any tell me why it is doing like that, I am completely new to nsis script

System::Call 'kernel32::GetLogicalDrives()i.r0'
StrCpy $1 $windir 3 ; Fallback if things go wrong
StrCpy $2 0
StrCpy $4 65 ; 'A'
loop:
    IntOp $3 $0 & 1
    ${If} $3 <> 0
        IntFmt $3 "%c:\" $4
        MessageBox MB_OK "Drive : $3"
        System::Call 'kernel32::GetDriveType(t,.r3)i.r5'
        MessageBox MB_OK "Value of 5555555: $5"
        StrCmp $5 5 0 NoDrive
            MessageBox MB_OK "Found drive $3"
            StrCpy $1 $3
        Nodrive:
            ;do nothing
    ${EndIf}
    IntOp $4 $4 + 1
    IntOp $0 $0 >> 1
StrCmp $0 0 "" loop
System::Call 'kernel32::GetDriveType(t,"D:\")i.r5'
StrCmp $5 5 0 NoDr
    MessageBox MB_OK "Found D as $D"
NoDr:

Answer 1

The correct syntax is System::Call 'kernel32::GetDriveType(tr#)i.r#' (Comma is parameter separator and . means no input and you have input in this case):

!include LogicLib.nsh
System::Call 'kernel32::GetLogicalDrives()i.r0'
StrCpy $2 0
StrCpy $4 65 ; 'A'
loop:
    IntOp $3 $0 & 1
    ${If} $3 <> 0
        IntFmt $3 "%c:\" $4
        System::Call 'kernel32::GetDriveType(tr3)i.r5'
        DetailPrint "$3=$5"
    ${EndIf}
    IntOp $4 $4 + 1
    IntOp $0 $0 >> 1
StrCmp $0 0 "" loop