Question

hi suppos I have this table’s fields : Employees

id , firstname , lastname , birthdate

and I want to make privacy on some fields so I created this table containing these fields

tableName, ColumnName , PrivacyType [Visible/Notvisible]

and when Selecting a row from the first table I don’t want to get the fields that have
privacy type = NotVisible

any idea

Answer 1

Generally, if you need some columns/rows hidden from a (set of) users, you’d implement a view for them. You’d then deny SELECT on the base table. The view definition would only reference those columns that you want to make accessible to the group of users you grant SELECT on the view to.

Once you have access going via views, as I say, you can implement more complex requirements, such as row level security.

(You can do something ugly in your views, if you’re set on having the privacy settings change dynamically, but I wouldn’t recommend it):

create table dbo.T1 (
    ID int not null,
    Col1 varchar(10) not null,
    Col2 varchar(10) not null,
    Col3 varchar(10) not null
)
go
create table dbo.Privacy (
    Schemaname sysname not null,
    Tablename sysname not null,
    Columnname sysname not null,
    Hidden bit not null
)
go
insert into dbo.T1 (ID,Col1,Col2,Col3)
select 1,'abc','def','ghi' union all
select 2,'ZYX','WVU','TSR'
go
insert into dbo.Privacy (Schemaname,Tablename,Columnname,Hidden)
select 'dbo','T1','Col2',1
go
create function dbo.ShowColumn (
    @Schema sysname,
    @Table sysname,
    @Column sysname
)
returns int
as
begin
    if exists(select * from dbo.Privacy where Schemaname = @Schema and Tablename = @Table and Columnname = @Column and Hidden=1)
    begin
        return 0
    end
    return 1
end
go
create view dbo.Virtual_T1 (ID,Col1,Col2,Col3)
as
    select
        ID,
        CASE WHEN 1 = dbo.ShowColumn('dbo','T1','Col1') THEN Col1 ELSE '' END,
        CASE WHEN 1 = dbo.ShowColumn('dbo','T1','Col2') THEN Col2 ELSE '' END,
        CASE WHEN 1 = dbo.ShowColumn('dbo','T1','Col3') THEN Col3 ELSE '' END
    from
        dbo.T1
go
select * from dbo.Virtual_T1

Result:

ID  Col1    Col2    Col3
1    abc             ghi
2    ZYX             TSR