Question

How can I can sort based on a key word? I have a kind-of complicated list and am wondering if I can sort it. Here is an example:

enter code here Room Name: RM145 
                ,ID,user Name
                ,300,NOS
                ,100,NOT
                Room Name: RM370 
                ,ID,user Name
                ,300,NOS
                Room Name: RM471  
                ,ID,user Name
                ,300,POS
                ,100,NOT
                Room Name: RM349  
                ,ID,user Name
                ,301,NOS
                ,100,NOT
                ,500,COS

My objective is to sort this list based on “Room Name“.

I have the file in both plain text and CSV. I don’t know which one is will be easier to sort. Does anyone have suggestions?

Answer 1

With GNU awk 4:

awk 'END {
  PROCINFO["sorted_in"] = "@ind_num_asc"
  for (R in r)
    print r[R]
  }
/Room Name:/ {
  rn = substr($NF, 3)
  }
{
  r[rn] = r[rn] ? r[rn] ORS $0 : $0
  }' infile   

This one should work with older GNU awk versions:

WHINY_USERS=  awk 'END {
  for (R in r)
    print r[R]
  }
/Room Name:/ {
  rn = sprintf("%15s", substr($NF, 3))
  }
{
  r[rn] = r[rn] ? r[rn] ORS $0 : $0
  }' infile