Question

How can I check a variable is defined before or not within the let construct?

 (let (((if (boundp 'a)
           'a
         'dummy) t))
   (message "I made this work"))

What I am trying to do is to check whether or not a is bounded before, if it is already, bind it to t locally. otherwise don’t care about a at all.

Answer 1

The code fails with: (wrong-type-argument symbolp (if (boundp (quote a)) (quote a) (quote dummy))), indicating that the let special form* does not evaluate that argument (although that list would evaluate to a symbol, the list itself is not a symbol).

Here’s a simple-but-flawed alternative approach which creates a local binding for a regardless, but then unbinds it in that local scope if it was unbound originally.

(let ((a (if (boundp 'a) t nil)))
  (or a (makunbound 'a))
  ;; do things
  )

The flaw is that if a was initially unbound, you would want an assignment to a within that local scope to outlive the local scope, and it won’t with this approach.

Initially I was thinking you’d need to forego let entirely to get around that issue, and just use something like this:

(when (boundp 'a)
  (setq a-backup a
        a t))
;; do things
(when (boundp 'a-backup)
  (setq a a-backup)
  (makunbound 'a-backup))

Then I realised that, as with so many things, macros are the answer:

(defmacro let-if-bound (var value &rest body)
  "Bind variable VAR to VALUE only if VAR is already bound."
  (declare (indent 2))
  `(if (boundp ',var)
       (let ((,var ,value))
         ,@body)
     (progn ,@body)))

(let-if-bound a t
  ;; do things
  )

(*) A “special form” is a primitive function specially marked so that its
arguments are not all evaluated. Most special forms define control
structures or perform variable bindings–things which functions cannot
do.

Each special form has its own rules for which arguments are evaluated
and which are used without evaluation. Whether a particular argument is
evaluated may depend on the results of evaluating other arguments.