Question

How can I deny access (only to write) to a file for other processes? I will read\write a file all time.

I use

FileOpen('c:\1.txt', fmOpenReadWrite or fmShareDenyWrite)

but after (starting to load the file to StringList) I get error

Cannot open file C:\1.txt. The process cannot access the file because it is being used by other process.”

Only I open the file.

Answer 1

Here, the error message is actually slightly misleading. The reason you can’t load into the stringlist is because you already opened the file in read/write.

if you check the implementation of TStrings.LoadfromFile:

procedure TStrings.LoadFromFile(const FileName: string);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
  try
    LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

You see that it tries to open the file with a “DenyWrite” condition, but you already opened the file in write mode. That is the reason why it fails.

You can work around that by using LoadFromStream instead.

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TStream;
begin
  Stream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyNone);
  try
    Stringlist.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

Note that you will need to use fmShareDenyNone for this to work in that situation. Then again, you could probably reuse the Read/Write handle you got from your OpenFile, probably do something like this:

procedure TForm1.Button1Click(Sender: TObject);
var
  Stream: TStream;
  iPosition : Int64;
begin
  Stream := THandleStream.Create(FHandle); //FHandle is the read/write handle returned by OpenFile
  try
    iPosition := Stream.Position;
    Stream.Seek(0, soFromBeginning);
    Stringlist.LoadFromStream(Stream);
    Stream.Position := iPosition;
    //Restore stream position.
  finally
    Stream.Free;
  end;
end;

But be advised that these approach might have a few “gotchas” I’m unaware of.