Question

How can I determine if I’m in the final loop of a For Each statement in VB.NET?

Answer 1

The generally, collections on which you can perform For Each on implement the IEnumerator interface. This interface has only two methods, MoveNext and Reset and one property, Current.

Basically, when you use a For Each on a collection, it calls the MoveNext function and reads the value returned. If the value returned is True, it means there is a valid element in the collection and element is returned via the Current property. If there are no more elements in the collection, the MoveNext function returns False and the iteration is exited.

From the above explanation, it is clear that the For Each does not track the current position in the collection and so the answer to your question is a short No.

If, however, you still desire to know if you’re on the last element in your collection, you can try the following code. It checks (using LINQ) if the current item is the last item.

For Each item in Collection
    If item Is Collection.Last Then
        'do something with your last item'
    End If
Next

---

It is important to know that calling Last() on a collection will enumerate the entire collection. It is therefore not recommended to call Last() on the following types of collections:

• Streaming collections
• Computationally expensive collections
• Collections with high tendency for mutation

For such collections, it is better to get an enumerator for the collection (via the GetEnumerator() function) so you can keep track of the items yourself. Below is a sample implementation via an extension method that yields the index of the item, as well as whether the current item is the first or last item in the collection.

<Extension()>
Public Iterator Function EnumerateEx(Of T)(collection As IEnumerable(Of T))
    As IEnumerable(Of (value As T, index As Integer, isFirst As Boolean, isLast As Boolean))

    Using e = collection.GetEnumerator()
        Dim index = -1
        Dim toYield As T

        If e.MoveNext() Then
            index += 1
            toYield = e.Current
        End If

        While e.MoveNext()
            Yield (toYield, index, index = 0, False)
            index += 1
            toYield = e.Current
        End While

        Yield (toYield, index, index = 0, True)
    End Using
End Function

Here is a sample usage:

Sub Main()
    Console.WriteLine("Index   Value   IsFirst   IsLast")
    Console.WriteLine("-----   -----   -------   ------")

    Dim fibonacci = {0, 1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89}

    For Each i In fibonacci.EnumerateEx()
        Console.WriteLine(String.Join("   ", $"{i.index,5}",
                                             $"{i.value,5}",
                                             $"{i.isFirst,-7}",
                                             $"{i.isLast,-6}"))
    Next

    Console.ReadLine()
End Sub

Output

Index   Value   IsFirst   IsLast
-----   -----   -------   ------
    0       0   True      False
    1       1   False     False
    2       1   False     False
    3       2   False     False
    4       3   False     False
    5       5   False     False
    6       8   False     False
    7      13   False     False
    8      21   False     False
    9      34   False     False
   10      55   False     False
   11      89   False     True