Question

How can I exclude result prefixes from an XQuery similiar to the XSLT exclude-result-prefixes attribute in XSL.

Currently my XQuery generates namespace prefixes for namespaces that are not part of the result set, but were part of the original payload.

Answer 1

XQuery doesn’t really have a built-in feature like the exclude-result-prefixes in XSLT. The serialization extension doesn’t seem to help there either. So you will have to do it yourself by processing the end result just before you return it. Shouldn’t be difficult though.

The xqueryfunctions website has functions that could help, like functx:change-element-names-deep ( http://www.xqueryfunctions.com/xq/functx_change-element-names-deep.html ), but that doesn’t really fit the bill here. So, here a more specific solution of my own:

declare function local:remove-prefixes($node as node(), $prefixes as xs:string*) {
    typeswitch ($node)
    case element()
        return
            if ($prefixes = ('#all', prefix-from-QName(node-name($node)))) then
                element {QName(namespace-uri($node), local-name($node))} {
                    $node/@*,
                    $node/node()/local:remove-prefixes(., $prefixes)
                }
            else
                element {node-name($node)} {
                    $node/@*,
                    $node/node()/local:remove-prefixes(., $prefixes)
                }
    case document-node()
        return
            document {
                $node/node()/local:remove-prefixes(., $prefixes)
            }
    default
        return $node
};

HTH!