Question

how can i Integration all texts from a column in a form to a textBox ?

this code can add all text from table to textbox in form

Set db = CurrentDb
Set rs = db.OpenRecordset("names")
For i = 1 To rs.RecordCount

text1.SetFocus
text1.Text = text1.Text & " " & rs(1)

rs.MoveNext

Next i

is it any way to add all text from Fields in form in to textbox in same form?

Answer 1

Replace your sub com1_Click with following block. Hope this helps . . .

Private Sub com1_Click()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strNames As String
    Dim strSQL As String

    ' Following line gets the query of the form
    strSQL = Me.RecordSource
    ' Alternatively, you can replace this line with your own select query
    ' For eg.
    ' strSQL = "Select * from Table1 Where [_ID] In (1,2)"


    Set db = CurrentDb
    Set rs = db.OpenRecordset(strSQL)

    strNames = ""

    'Following loop is for going through all the records
    While Not rs.EOF
        'Following line is for collecting values of Name1 Field of your table
        strNames = strNames & " " & rs("Name1")
        rs.MoveNext
    Wend

    ' Populating the textbox with values collected from your table
    text3 = Trim(strNames)

    ' Final cleanup
    rs.Close
    Set rs = Nothing
    Set db = Nothing
End Sub