Question

How can I use XMLParser to get the item->@url, item->@replace and item->”value inside”
for the content as a string of the node where item->@cone=”one”?

<cstep>
  <item  cone="one" 
         url="http://google.com/{ccc}/cthree"
         replace="{ccc}">
            <itemsub conesub="conesub">
                    <itemsubsub  conesubsub="conesubsub" />
            </itemsub>       
  </item>
  <item  cone="two" 
         url="http://google.com/{ccc}/cthree"
         replace="{ccc}">
            <itemsub conesub="conesub">
                    <itemsubsub  conesubsub="conesubsub" />
            </itemsub>       
  </item>
</cstep>

Answer 1

XML::Twig:

use warnings;
use strict;
use XML::Twig;

my $str = <<EOF;
    <cstep>
      <item  cone="one" 
             url="http://google.com/{ccc}/cthree"
             replace="{ccc}">
                <itemsub conesub="conesub">
                        <itemsubsub  conesubsub="conesubsub" />
                </itemsub>       
      </item>
      <item  cone="two" 
             url="http://google.com/{ccc}/cthree"
             replace="{ccc}">
                <itemsub conesub="conesub">
                        <itemsubsub  conesubsub="conesubsub" />
                </itemsub>       
      </item>
    </cstep>
EOF

my $t = XML::Twig->new(twig_handlers => {'cstep/item' => \&item });
$t->parse($str);

sub item {
    my ($t, $item) = @_;
    if ($item->att('cone') eq 'one') {
        print $item->att('url'    ), "\n";
        print $item->att('replace'), "\n";
    }
}

__END__

http://google.com/{ccc}/cthree
{ccc}

UPDATE: To answer a question in the comments about assigning to $url outside of the sub:

my $t = XML::Twig->new(twig_handlers => {'cstep/item' => \&item });
my $url;
$t->parse($str);
print "$url\n";

sub item {
    my ($t, $item) = @_;
    if ($item->att('cone') eq 'one') {
        $url = $item->att('url');
        print $item->att('replace'), "\n";
    }
}