Question

How can I write this in Delphi code?

[DllImport("FT_ND_API.dll")]
public static extern uint epas_CreateContext(out IntPtr hContextHandle, 
    uint ulFlags, uint ulApiVersion);

[DllImport("FT_ND_API.dll")]
public static extern uint epas_OpenDevice(IntPtr hContextHandle, 
    uint ulQueryType, IntPtr pQueryData);

[DllImport("FT_ND_API.dll")]
public static extern uint epas_GetProperty(IntPtr hContextHandle, uint ulFlags, 
    IntPtr pRefData, byte[] pPropData, uint ulPropSize);

[DllImport("FT_ND_API.dll")]
public static extern uint epas_CreateDir(IntPtr hContextHandle, uint ulFlags, 
    String pucName, String pucGuid, ref WDirInfo pDirInfo, uint ulSizeOfDirInfo);

Answer 1

Like this:

function epas_CreateContext(
  out hContextHandle: NativeInt; 
  ulFlags: Cardinal; 
  ulApiVersion: Cardinal
): Cardinal; stdcall; external 'FT_ND_API.dll';

function epas_OpenDevice(
  hContextHandle: NativeInt; 
  ulQueryType: Cardinal; 
  pQueryData: IntPtr
): Cardinal; stdcall; external 'FT_ND_API.dll';

function epas_GetProperty(
  hContextHandle: NativeInt; 
  ulFlags: Cardinal; 
  pRefData: NativeInt; 
  pPropData: PByte; 
  ulPropSize: Cardinal
): Cardinal; stdcall; external 'FT_ND_API.dll';

function epas_CreateDir(
  hContextHandle: NativeInt; 
  ulFlags: Cardinal; 
  pucName: PAnsiChar; 
  pucGuid: PAnsiChar; 
  var pDirInfo: WDirInfo; 
  ulSizeOfDirInfo: Cardinal
): Cardinal; stdcall; external 'FT_ND_API.dll';

Notes:

• IntPtr is a pointer sized integer. In Delphi that is NativeInt.
• uint is an unsigned 32 bit integer, Cardinal in Delphi.
• string gets marshalled to a C string, pointer to null-terminated string. Since there is no CharSet specified, the default of CharSet.Ansi is used. That’s PAnsiChar in Delphi.
• No CallingConvention is specified so the default of CallingConvention.StdCall applies. So, that’s stdcall in Delphi.
• The byte[] is an array of bytes. That’s marshalled as a pointer to the first byte of the array. So, PByte in Delphi.
• You will also need to translate WDirInfo to Delphi. It looks like it might be a struct.

You might be better off working from the C++ header file rather than the p/invoke declarations. It’s always best to work from the original source of an interface definition.