Question

How do i check if a certain value is the largest element in an array? this is in the Ada language. I have the function finding the largest element, and it works.. now i want to run a post condition that check that that value is the largest.

Answer 1

Loop through the array, failing if you find an element that is larger or if you don’t find an element that is equal?

function Check_Largest (In_Array : Array_Type; Value : Element_Type)
  return Boolean
is
   Matched : Boolean := False;
begin
   for J in In_Array'Range loop
      if In_Array (J) > Value then
         return False;
      elsif In_Array (J) = Value then
         Matched := True;
      end if;
   end loop;
   return Matched;
end Check_Largest;

Revisiting this in 2020, post Ada 2012, a pair of quantifiers might do the trick; see the postcondition of Largest_Member:

procedure Largest
with SPARK_Mode
is
   type Arr is array (Positive range <>) of Natural;

   function Largest_Member (Of_Array : Arr) return Natural
   with
     Pre => Of_Array'Length > 0,
     Post =>
       (for all E of Of_Array => E <= Largest_Member'Result)
       and
       (for some E of Of_Array => E = Largest_Member'Result);

   function Largest_Member (Of_Array : Arr) return Natural is
      Result : Integer := -1;
   begin
      for J in Of_Array'Range loop
         if Of_Array (J) > Result then
            Result := Of_Array (J);
         end if;
         pragma Loop_Invariant
           ((for all F of Of_Array (Of_Array'First .. J) => F <= Result)
            and
            (for some F of Of_Array (Of_Array'First .. J) => F = Result));
      end loop;
      return Result;
   end Largest_Member;
begin
   null;
end Largest;