Question

How do I find and remove repeated words from sentences in PowerPoint?

As a grammar check I want to find double words which are typed by mistake. For example:

Stackoverflow is a a greate site

In this example, one “a” would be removed.

Answer 1

My friend, you are embarking on a dangerous mission if you are trying to re-invent automatic grammar checking. Natural language is filled with exceptions guaranteed to evade whatever small set of rules you think will do the job.

Anyhow, below is a lucidly naive stab at it. Now, this code works for the example you gave. It will remove that extra “a”. But please be aware that not every repeated word should be removed if you care about preserving grammar, syntax and semantics. Automatically removing repeated “that”s will work wonders on this:

I love that that site.

but it will alter the writer’s intent on this by taking the grammar down to a very informal level:

She said that that is a great site.

and removing repeats will ruin absolutely everything here:

That that is is that that is not is not that that is that that is is not true is not true.

not to mention this:

Buffalo buffalo Buffalo buffalo buffalo buffalo Buffalo buffalo.

Be prepared for disaster! But anyway, the code works for your example (and more) and provides a framework for you to build upon and to fine-tune such that it works in the majority of cases relevant to you.

Dim shp As Shape
Dim str As String
Dim wordArr() As String
Dim words As Collection
Dim iWord As Long
Dim thisWord As String
Dim nextWord As String
Dim newText As String

For Each shp In ActivePresentation.Slides(1).Shapes
    If shp.HasTextFrame Then
        'Get the text
        str = shp.TextFrame.TextRange.Text
        'Split it into an array of words
        wordArr = Split(str, " ")

        'Transfer to a Collection, easier to deal with than array.
        Set words = New Collection
        For iWord = LBound(wordArr) To UBound(wordArr)
            words.Add wordArr(iWord)
        Next iWord

        'Look for repeats.
        For iWord = words.Count - 1 To 1 Step -1
            thisWord = words.Item(iWord)
            nextWord = words.Item(iWord + 1)

            'Make sure commas don't get in the way of a comparison
            'e.g. "This is a great, great site" is fine
            'but "This site is great great, and I love it" is not.
            nextWord = Replace(nextWord, ",", "")
            'Add whatever other filtering you feel is appropriate.
            'e.g. period, case sensitivity, etc.

            If LCase(thisWord) = LCase(nextWord) Then
                If LCase(thisWord) = "that" Then
                    'Do nothing. "He said that that was great." is ok.
                    'This is just an example. "had" is another.
                    'Add more filtering here.
                Else
                    words.Remove iWord + 1
                End If
            End If
        Next iWord

        'Assemble the text with repeats removed.
        newText = ""
        For iWord = 1 To words.Count
            newText = newText & words.Item(iWord) & " "
        Next iWord

        'Finally, put it back on the slide.
        shp.TextFrame.TextRange.Text = newText
    End If
Next shp