Question

How do I only add a namespace to the root element?

My XML:

<Envelope>
    <from>
        <contents />
    </from>
</Envelope>

My desired output:

<Envelope xmlns:tns="Foo">
    <from>
        <contents />
    </from>
</Envelope>

I can only get “xmlns=’Foo'” using this, not “xmlns:tns=..”:

<xsl:element name="{local-name()}" namespace="Foo" >
        <xsl:copy-of select="attribute::*"/>
        <xsl:apply-templates />
</xsl:element>

Answer 1

Here is a complete transformation:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:tns="Foo">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:template match="node()|@*">
         <xsl:copy>
           <xsl:apply-templates select="node()|@*"/>
         </xsl:copy>
     </xsl:template>

     <xsl:template match="/*">
      <xsl:element name="{name()}">
       <xsl:copy-of select=
        "document('')/*/namespace::*[name()='tns']"/>
       <xsl:apply-templates/>
      </xsl:element>
     </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the provided XML document:

<Envelope>
    <from>
        <contents />
    </from>
</Envelope>

the wanted, correct result is produced:

<Envelope xmlns:tns="Foo">
   <from>
      <contents/>
   </from>
</tns:Envelope>