Question

How do I set up a fall-back file for an IceCast server?

Answer 1

If you happen to be using a very useful toolset named liquidsoap with icecast2 then you ought to be thrilled with the follow example, which will play a directory of sound files, or if there is a live stream broadcast then it will fadeout the playlist, play a "jingle" sound file, then fadeup the live stream. Aside from the silly urls this was pulled from a working environment.

Installing liquidsoap was as painless as apt-get install. If you want to use mp3 then apt-get install lame and then switch to output.icecast.lame(). Create a file with a .liq extension (example.liq), then chmod +x example.liq and you’re off to the ./races

#!/usr/bin/liquidsoap 
# use the -d flag for daemon mode

set("log.file",false)
set("log.stdout",true)
set("log.level",3)
set("harbor.icy",true)

default =  single("say:How are you gentlemen!! 
             all your base are belong to us. 
             You are on the way to destruction.                      
             What you say!!                      
             You have no chance to survive make your time! 
             HA! HA! HA! HA! HA!")

jingles = playlist("/home/edward/micronemez-jinglez") 

audio = playlist("/home/edward/micronemez-ogg")

#liveset = mksafe(input.http("http://audio.micronemez.com")) 
liveset = strip_blank(input.http("http://f-dt.com"))
liveset = rewrite_metadata([("artist", "FUTURE__DEATH__TOLL"),("title", "LIVE FROM YELLOW_HOUSE")], liveset) 

radio = fallback(track_sensitive=false,
         [skip_blank(liveset), audio, default])

radio = random(weights=[1,5],[ jingles, radio ]) 

output.icecast.vorbis( 
  host="futuredeathtoll.com",port=8000,password="hackme", 
  genre="Easy Listening",url="http://f-dt.com", 
  description="pirate radio",mount="micronemez-radio.ogg", 
  name="FUTURE__DEATH__TOLL ((YELLOW_HOUSE))",radio)

some very useful links:

http://savonet.sourceforge.net/doc-svn/cookbook.html

http://oshyn.com/_blog/General/post/Audio_and_Video_Streaming_with_Liquidsoap_and_Icecast/

http://wiki.sourcefabric.org/display/LS/WikiStart