Question

How I can check the date using a calender , what I want to do is that a user insert a date in this way 2012/07/15 , and i want to check if this date exist in the calender .
for example if he insert 2012/14/13 or even 2012/02/31 , i tried to do that manually but its really hard , so my qustions are :

1. is there a native function(or even 3d party tools) to check date in calender ?

2. if the user insert date and hour , I want to give same result with different time zone places ?

Answer 1

The subroutine below is comprised of two parts. First it check the date given in 1st parameter and return ERRORLEVEL=1 if the date is bad. You may insert a year valid range if you wish (otherwise, remove the yyOK parts).

Then it takes a base hour and time-zone adjust in 2nd and 3rd parameters and show the adjusted date.

:validateDate result= YYYY/MM/DD [HH HHAdjust]
setlocal EnableDelayedExpansion
set i=0
for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do (
   set /A i+=1
   set daysPerMonth[!i!]=%%a
)
set result=Invalid date
for /F "tokens=1-3 delims=/" %%a in ("%2") do set yy=%%a& set mm=%%b& set dd=%%c
set /A yy=%yy%, mm=10%mm% %% 100, dd=10%dd% %% 100, yyMOD4=yy%%4 >NUL 2>&1 || goto exit
if %yyMOD4% equ 0 set daysPerMonth[2]=29
set /A yyOK=0, mmOK=0, ddOK=0
rem Modify year limits as you wish (or remove they):
if %yy% geq 1900 if %yy% leq 2015 set yyOK=1
if %mm% geq 1 if %mm% leq 12 set mmOK=1
id %dd% geq 1 if %dd% leq !daysPerMonth[%mm%]! set ddOK=1
set /A dateOK=yyOK*mmOK*ddOK
if %dateOK% neq 1 goto exit
rem Date is correct
set result=%yy%/%mm%/%dd%

rem Adjust the hour to different time zone, if given
rem %3=base hour, %4=adjust with sign (+ or -)
if "%4" equ "" goto exit
set /A newHH=10%3 %% 100 %4
if %newHH% gtr 23 (
   rem Pass to next day
   set /A newHH-=24, dd+=1
   if !dd! gtr !daysPerMonth[%mm%]! (
      set /A dd=1, mm+=1
      if !mm! gtr 12 (
         set /A mm=1, yy+=1
      )
   )
)
if %newHH% lss 1 (
   rem Pass to previous day
   set /A newHH+=24, dd-=1
   if !dd! lss 1 (
      set /A mm-=1
      if !mm! lss 1 (
         set /A mm=12, yy-=1
      )
      for %%m in (!mm!) do (
         set /A dd=daysPerMonth[%%m]
      )
   )
)
set result=%yy%/%mm%/%dd% %newHH%

:exit
endlocal & set %1=%result%
exit /B

Test this program and report any problem.

EDIT: I have modified previous program to fit new OP’s requirements.

The subroutine no longer returns an ERRORLEVEL value with the result. It must be called now with a new first parameter that indicate the variable that will receive the result, that will be “Invalid date” if original date is bad. If a base and adjustment hours are given, returned value include the adjusted date and hour. For example:

call validate.bat adjusted= 2012/3/5 3 -2
if "%adjusted%" neq "Invalid date" (
   echo Adjusted date and hour are: %adjusted%
)

Antonio