Question

How to make the thumbnail a size of 84×84 pixel?

function createThumbs()
{
    _myThumbData = new BitmapData(photodefault.width,photodefault.height,false,0xffffff);
    photothumbs.t1.addChild(createBitmap(_myThumbData));
}

function createBitmap(bmd:BitmapData):Bitmap
{
    var bitmap:Bitmap = new Bitmap(bmd);
    bitmap.smoothing = true;
    bitmap.scaleX = bitmap.scaleY = 0.2;
    return bitmap;
}

Thanks.
Uli

Answer 1

Based on your comment, you need to resize and maintain the aspect ratio.
You need to compute the aspect ratio for the original image and the container, then resize the container based on the larger ratio. here’s what I mean:

        function createThumbs()
        {
            _myThumbData = new BitmapData(photodefault.width,photodefault.height,false,0xffffff);
            photothumbs.t1.addChild(createBitmap(_myThumbData));
        }

        function createBitmap(bmd:BitmapData):Bitmap
        {
            var bitmap:Bitmap = new Bitmap(bmd);
            bitmap.smoothing = true;
            setSize(bitmap, bmd.width, bmd.height, 84, 84);
            return bitmap;
        }
        function setSize(target:DisplayObject, contentWidth:Number, contentHeight:Number, targetWidth:Number, targetHeight:Number):void {
            var w:Number = targetWidth;
            var h:Number = targetHeight;
            // maintain aspect ratio
            var containerRatio:Number = targetWidth / targetHeight;
            var imageRatio:Number = contentWidth / contentHeight;
            if (containerRatio < imageRatio) h = w / imageRatio;
            else                             w = h * imageRatio;
            target.width = w;
            target.height = h;
            //centre content - this might change based on your setup
            target.x = (targetWidth - w) * .5;
            target.y = (targetHeight -h) * .5;
        }