Question

How to set the constant series value in excel using apple script.

 tell worksheet 1 of active workbook
      set obj to make new chart object at end with properties{ 
                                     left position:120,top:50,width: 120,height:150}  
 set ochart to chart of obj    
      tell ochart
           make new series at end with properties {series values:"={1}"}
      end tell
 end tell

 This script through error(Microsoft Excel got an error:Can't make class series)

Please replay

Answer 1

I’m not sure if my syntax is wrong or if this is a bug.

You would expect to be able to create a new series with a constant by using:

set newSeries to make new series at end with properties {name:"tempSeriesName", series values:{50}}

However, I have only been able to use a range to create the series:

set newSeries to make new series at end with properties {name:"tempSeriesName", series values:"A2"}

However, once the series has been created you can update the value with:

set series values to {50}

My workaround has been to find the first blank cell in column A and populate it with a value. I then use this cell to create the range, update the range with the constant, and then revert the temporary cell to a blank.

tell application "Microsoft Excel"
    tell worksheet "Sheet1" of active workbook
        -- Find the first empty cell and populate it with 1
        set counter to 0
        repeat
            set counter to counter + 1
            set myRange to ("A" & counter as text)
            if value of range myRange = "" then
                set value of range myRange to "1"
                exit repeat
            end if
        end repeat

        set obj to make new chart object at end with properties {name:"chart1", left position:20, top:88, width:33, height:90}
        set ochart to chart of obj
        tell ochart
            set chart type to column clustered
            -- create the chart with the temporary value
            set newSeries to make new series at end with properties {name:"tempSeriesName", series values:myRange}
            -- update the chart with your constant value
            set series values of newSeries to {50}
        end tell
        set value of range myRange to ""
    end tell
end tell