Question

How to split one lineitem depends on its fields?

Answer 1

To do this, you could create an xsl:key to match non-Split elements (such as Cash and CreditCard), and using the most preceding Split element as the look-up.

<xsl:key name="Acc" 
 match="AccCode[AccCodeType != 'Split']" 
 use="generate-id(preceding-sibling::AccCode
   [AccCodeType = 'Split']
   [SuppDocNo/RefNo = current()/SuppDocNo/RefNo][1])" />

Then, when you match on an AccCode of split you can get all the associated elements by looking them up in the key

<xsl:apply-templates select="key('Acc', generate-id())" />

Thus with the following XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="Acc" match="AccCode[AccCodeType != 'Split']" use="generate-id(preceding-sibling::AccCode[AccCodeType = 'Split'][SuppDocNo/RefNo = current()/SuppDocNo/RefNo][1])"/>

   <xsl:template match="/">
      <xsl:apply-templates select="//AccCode[AccCodeType = 'Split']"/>
   </xsl:template>

   <xsl:template match="AccCode[AccCodeType = 'Split']">
      <ITEM>
         <LineItemNo>
            <xsl:value-of select="../LineNo"/>
         </LineItemNo>
         <SplitPercentage>
            <xsl:value-of select="PrimDocNo/RefNo"/>
         </SplitPercentage>
         <SplitNo>
            <xsl:value-of select="SuppDocNo/RefNo"/>
         </SplitNo>
         <xsl:apply-templates select="key('Acc', generate-id())"/>
      </ITEM>
   </xsl:template>

   <xsl:template match="AccCode[AccCodeType != 'Split']">
      <xsl:element name="{AccCodeType}">
         <xsl:value-of select="PrimDocNo/RefNo"/>
      </xsl:element>
   </xsl:template>
</xsl:stylesheet>

When this is applied to your sample XML, the following is output:

<ITEM>
   <LineItemNo>01</LineItemNo>
   <SplitPercentage>100.00</SplitPercentage>
   <SplitNo>01</SplitNo>
   <Cash>100</Cash>
   <CreditCard>200</CreditCard>
</ITEM>
<ITEM>
   <LineItemNo>02</LineItemNo>
   <SplitPercentage>50.00</SplitPercentage>
   <SplitNo>02</SplitNo>
   <Cash>300</Cash>
   <CreditCard>400</CreditCard>
</ITEM>
<ITEM>
   <LineItemNo>02</LineItemNo>
   <SplitPercentage>50.00</SplitPercentage>
   <SplitNo>01</SplitNo>
   <Cash>500</Cash>
   <CreditCard>600</CreditCard>
</ITEM>