Question

I am a student working on a project with flash. I am simply trying to make a flash game using Actionscript 3 in Adobe Flash CS5. Everything is working fine, i can walk and jump, but I want the game to restart if the Main character touches an object and dies (like spikes in a pit). I have a main menu in frame 1 and the first level on frame 2. The main character is called “player_mc” and the object that kills him is called “dies”. Help and tips is very much appreciated.

Code:

//The Code For The Character (Player_mc)
import flash.events.KeyboardEvent;
import flash.events.Event;

var KeyThatIsPressed:uint;
var rightKeyIsDown:Boolean = false;
var leftKeyIsDown:Boolean = false;
var upKeyIsDown:Boolean = false;
var downKeyIsDown:Boolean = false;

var playerSpeed:Number = 20;
var gravity:Number = 1;
var yVelocity:Number = 0;
var canJump:Boolean = false;
var canDoubleJump:Boolean = false;

stage.addEventListener(KeyboardEvent.KEY_DOWN, PressAKey);
stage.addEventListener(KeyboardEvent.KEY_UP, ReleaseAKey);


//This two functions cllapsed is the keybindings that the game uses
function PressAKey(event:KeyboardEvent):void
{
    if(event.keyCode == Keyboard.D)
    {
        rightKeyIsDown = true;
    }
    if(event.keyCode == Keyboard.A)
    {
        leftKeyIsDown = true;
    }
    if(event.keyCode == Keyboard.SPACE)
    {
        upKeyIsDown = true;
    }
    if(event.keyCode == Keyboard.S)
    {
        downKeyIsDown = true;
    }
}

function ReleaseAKey(event:KeyboardEvent):void
{
    if(event.keyCode == Keyboard.D)
    {
        rightKeyIsDown = false;
    }
    if(event.keyCode == Keyboard.A)
    {
        leftKeyIsDown = false;
    }
    if(event.keyCode == Keyboard.SPACE)
    {
        upKeyIsDown = false;
    }
    if(event.keyCode == Keyboard.S)
    {
        downKeyIsDown = false;
    }
}

//Player animations
player_mc.addEventListener(Event.ENTER_FRAME, moveThePlayer);

function moveThePlayer(event:Event):void 
{
    if(!canJump || rightKeyIsDown && !canJump || leftKeyIsDown && !canJump)
    {
        player_mc.gotoAndStop(3);
    }
    if(!upKeyIsDown && !rightKeyIsDown && !leftKeyIsDown && canJump)
    {
        player_mc.gotoAndStop(1);
    }
    if(rightKeyIsDown && canJump || leftKeyIsDown && canJump)
    {
        player_mc.gotoAndStop(2);
    }
    //Animation stops here

    if(rightKeyIsDown) 
    {
        floor_mc.x -= playerSpeed;
        dies.x -= playerSpeed;
        player_mc.scaleX = 0.3;
    }
    if(leftKeyIsDown) 
    {
        floor_mc.x += playerSpeed;
        dies.x += playerSpeed;
        player_mc.scaleX = -0.3;
    }
    if(upKeyIsDown && canJump)
    {
        yVelocity = -18;
        canJump = false;
        canDoubleJump = true;
    }
    if(upKeyIsDown && canDoubleJump && yVelocity > -2)
    {
        yVelocity =-13;
        canDoubleJump = false;
    }
    if(!rightKeyIsDown && !leftKeyIsDown && !upKeyIsDown)
    {
        player_mc.gotoAndStop(1);
    }
    yVelocity +=gravity

    if(! floor_mc.hitTestPoint(player_mc.x, player_mc.y, true))
    {
        player_mc.y+=yVelocity;
    }
    if(yVelocity > 20)
    {
        yVelocity =20;
    }

    for (var i:int = 0; i<10; i++)
    {
        if(floor_mc.hitTestPoint(player_mc.x, player_mc.y, true))
        {
            player_mc.y--;
            yVelocity = 0;
            canJump = true;
        }
    }
}

Answer 1

If I understand this right, when you die, you want to restart the level. To do this, you could save all your initial variables like player position, floor position, etc in an array, then on death, restore those variables to their corresponding object. However, when you get more complex and have lots and lots of objects, it could become tricky.

A simpler solution is to display a death screen of some sorts on another frame (lets call it frame 3) when you hit the dies object, and on that death screen when you press a restart button or after a certain time delay, it then goes back to frame 2 and restarts the level.

Example:

Put this in your moveThePlayer function:

if(dies.hitTestPoint(player_mc.x, player_mc.y, true))
{
    // remove all the event listeners
    player_mc.removeEventListener(Event.ENTER_FRAME, moveThePlayer);
    stage.removeEventListener(KeyboardEvent.KEY_DOWN, PressAKey);
    stage.removeEventListener(KeyboardEvent.KEY_UP, ReleaseAKey);

    gotoAndStop(3); // this has your "dead" screen on it.
}

And on frame 3, have something like:

import flash.events.MouseEvent;

retry_button.addEventListener(MouseEvent.CLICK, retry);

function retry(e:MouseEvent) {
    retry_button.removeEventListener(MouseEvent.CLICK, retry);

    // back to the level
    gotoAndStop(2);
}

You could also do something like storing a variable on which frame you want to go back to, so you have a single retry frame which can go to whatever level you were just on.