Question

I am a Web Developer who has primarily dealt with PHP and MySQL and now has to program almost exclusively in VB.Net. While I have had plenty of experience in Visual Basic in the past, I had almost none as it pertains to web. The learning curve is there, but not terrible.

I’m very familiar with retrieving information from a MySQL Database using PHP, but am now having to code in VB.Net and wanted to know if there is a similar process that doesn’t involve the drag and drop of Data Controllers in Visual Studio?

What I need to do is have a working page that checks for records in a database on page load, and if there are some present for a given time period, populate those records into multiple input fields.

Thanks in advance.

Answer 1

From Microsoft’s example for a SqlDataReader:

Depending on what controls you are going to populate, and how you are going to present the data, there may be a better way to set the datasource for those controls, but if you want to read a MS SQL Server db and process yourself, do something like this:

Option Explicit On 
Option Strict On 

Imports System.Data
Imports System.Data.SqlClient

Module Module1

Sub Main()
    Dim str As String = "Data Source=(local);Initial Catalog=Northwind;" _
   & "Integrated Security=SSPI;"
    ReadOrderData(str)
End Sub 

Private Sub ReadOrderData(ByVal connectionString As String)
    Dim queryString As String = _
        "SELECT OrderID, CustomerID FROM dbo.Orders;" 

    Using connection As New SqlConnection(connectionString)
        Dim command As New SqlCommand(queryString, connection)
        connection.Open()

        Dim reader As SqlDataReader = command.ExecuteReader()

        ' Call Read before accessing data. 
        While reader.Read()
            ReadSingleRow(CType(reader, IDataRecord))
        End While 

        ' Call Close when done reading.
        reader.Close()
    End Using 
End Sub 

Private Sub ReadSingleRow(ByVal record As IDataRecord)
   Console.WriteLine(String.Format("{0}, {1}", record(0), record(1)))

End Sub 

End Module