Question

I am coding with Perl on a Window 7 machine. I am able to extract data from the XML using the XPath code below

use strict;
use warning;

use XML::LibXML;

my $parser = XML::LibXML->new();
        my $doc    = $parser->parse_file($newfile);
        my $query  = "/tradenet/message/header/unique_ref_no/date/text( )";
        my($node)   = $doc->findnodes($query);
        $node->setData("$file_seq_number");  

However, when i use the same code on a different XML, the xpath from the second document looks as below:

/TradenetResponse/OutboundMessage/out:OutwardPermit/out:Declaration/out:Header/cac:UniqueReferenceNumber/cbc:SequenceNumeric

Together with the Perl code, this is what the extraction code looks like:

my $parser = XML::LibXML->new();
    my $doc    = $parser->parse_file($newfile);
    my $query  = "/TradenetResponse/OutboundMessage/out:OutwardPermit/out:Declaration/out:Header/cac:UniqueReferenceNumber/cbc:SequenceNumeric/text( )";
    my($node)   = $doc->findnodes($query);
    $node->setData("$file_seq_number");

Using the second code, I am unable to retrieve the data from the second XML. I receive this error “Can’t call method “setData”on an undefined value at Perl.pl line 5”.

Does the “:” character in the second XPATH address affecting the code?

Answer 1

You have to define what out, cac, and cbc mean in order for the XPath query to find the appropriate nodes:

my $doc = $parser->parse_file($newfile);
my $xpath_context = XML::LibXML::XPathContext->new($doc->documentElement());

# These URIs need to be the same as the ones in the source document
$xpath_context->registerNs('out', 'http://example.com/out.xsd');
$xpath_context->registerNs('cac', 'http://example.com/cac.xsd');
$xpath_context->registerNs('cbc', 'http://example.com/cbc.xsd');

my $query  = "/TradenetResponse/OutboundMessage/out:OutwardPermit/out:Declaration/out:Header/cac:UniqueReferenceNumber/cbc:SequenceNumeric/text( )";
my ($node) = $xpath_context->findnodes($query);

As promised, here is a working example. First, the test input file:

<?xml version="1.0"?>

<!-- input.xml -->

<TradenetResponse xmlns:a="http://example.com/out.xsd"
                  xmlns:b="http://example.com/cac.xsd"
                  xmlns:c="http://example.com/cbc.xsd">
  <OutboundMessage>
    <a:OutwardPermit>
      <a:Declaration>
        <a:Header>
          <b:UniqueReferenceNumber>
            <c:SequenceNumeric>1234</c:SequenceNumeric>
          </b:UniqueReferenceNumber>
        </a:Header>
      </a:Declaration>
    </a:OutwardPermit>
  </OutboundMessage>
</TradenetResponse>

And here is the working Perl script:

#!/usr/bin/perl

# parse.pl

use strict;
use warnings;
use XML::LibXML;

my $parser = XML::LibXML->new();

my $newfile = "input.xml";
my $doc = $parser->parse_file($newfile);
my $xpath_context = XML::LibXML::XPathContext->new($doc->documentElement());

# These URIs need to be the same as the ones in the source document
$xpath_context->registerNs('out', 'http://example.com/out.xsd');
$xpath_context->registerNs('cac', 'http://example.com/cac.xsd');
$xpath_context->registerNs('cbc', 'http://example.com/cbc.xsd');

# Query wrapped for clarity                                                                                                         
my $query = "/TradenetResponse/OutboundMessage/out:OutwardPermit" .
            "/out:Declaration/out:Header/cac:UniqueReferenceNumber" .
            "/cbc:SequenceNumeric/text()";

my ($node) = $xpath_context->findnodes($query);

print "Value: " . $node->getData() . "\n";

The output for me is:

sean@localhost:~xmltest$ ./parse.pl
Value: 1234