Question

I am creating a VB6 application, which reads information from an XML file and then copies a particular file to my local workstation. The XML looks something like the below;

<ArrayOfMediaFile xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
  <MediaFile>
    <fileName>Default.jpg</fileName> 
    <filePath>C:\Program Files\media</filePath> 
    <dateModified>2012-04-30T14:41:28.6893988-05:00</dateModified> 
    <Action>Add</Action> 
  </MediaFile>
  <MediaFile>
    <fileName>icon.jpg</fileName> 
    <filePath>C:\Program Files\media</filePath> 
    <dateModified>2012-04-30T15:43:31.2995396-05:00</dateModified> 
    <Action>Add</Action> 
  </MediaFile>
</ArrayOfMediaFile>

Now my application reads the file name and if the action node is “add” it copies the file and converts the action node to “keep”.

The Problem

What i wish to do now is to save this file after every operation. If while saving the XML there is any error, I should be able to make a copy of the XML which I can again use in the operation.

Answer 1

This code always backs up the XML file .xml to .backup, and then if successful, it saves to _Processed.xml. Hope that’s what you want.

Private Function ProcessFilesFromXml(ByRef the_sXmlFileName As String) As Boolean

    Dim nPosDot                         As Long
    Dim sXmlFileNamePrefix              As String
    Dim sXmlFileNameSuffix              As String
    Dim oXmlDoc                         As MSXML2.DOMDocument
    Dim oXmlMediaFileNode               As MSXML2.IXMLDOMElement
    Dim oXmlActionNode                  As MSXML2.IXMLDOMElement

    On Error GoTo ErrorHandler

    nPosDot = InStr(1, the_sXmlFileName, ".")

    If (nPosDot) Then
        sXmlFileNamePrefix = Left$(the_sXmlFileName, nPosDot - 1)
        sXmlFileNameSuffix = Mid$(the_sXmlFileName, nPosDot)
    Else
        sXmlFileNamePrefix = the_sXmlFileName
        sXmlFileNameSuffix = vbNullString
    End If

    ' First of all, back up the XML file <XmlFileList>.xml to <XmlFileList>.backup  . Overwrites existing backup file.
    FileCopy the_sXmlFileName, sXmlFileNamePrefix & ".backup"

    On Error GoTo ErrorHandler_ProcessingXml

    ' Load the Xml file <XmlFileList>.xml
    Set oXmlDoc = New MSXML2.DOMDocument
    oXmlDoc.Load the_sXmlFileName

    ' Iterate through each media file, and try to copy it.
    For Each oXmlMediaFileNode In oXmlDoc.selectNodes("/ArrayOfMediaFile/MediaFile")
        If Not CopyFileNameToLocalMachine(oXmlMediaFileNode.selectSingleNode("fileName").Text, oXmlMediaFileNode.selectSingleNode("filePath").Text) Then
            Set oXmlActionNode = oXmlMediaFileNode.selectSingleNode("Action")
            oXmlActionNode.Text = "keep"
        End If
    Next oXmlMediaFileNode

    ' Save under the name <XmlFileList>_Processed.xml
    oXmlDoc.save sXmlFileNamePrefix & "_Processed" & sXmlFileNameSuffix

    ' Since we got here, things must have been fine.
    ProcessFilesFromXml = True

Return_ProcessingXml:
    '
Exit Function

ErrorHandler_ProcessingXml:
    ProcessFilesFromXml = False
    Resume Return_ProcessingXml

ErrorHandler:
    Err.Raise Err.Number, Err.Source, Err.Description
End Function

Private Function CopyFileNameToLocalMachine(ByRef the_sFileName As String, ByRef the_sLocalPath As String)
    ' Your code here.
End Function