Question

I am currently making a batch file that merges both, the output from systeminfo, and ipconfig:

@ECHO OFF
pause
systeminfo > "%computername% SystemInfo.txt"
ipconfig >> "%computername% SystemInfo.txt"
"%computername% systeminfo.txt"

The code runs fine and nicely, also independently from OS version and OS language as far as I can tell. My problem though, lies with the systeminfo dump. It lists all 100+ hotfixes that have ever been installed in the machine that is runs on, making the txt file barely legible:

<useful info>
[01]: File 1
[02]: File 1
[03]: File 1
[04]: File 1
....
[150]: file 1
etc...
<useful info>

There’s also another problem, namely that this batch file has to run on computers that either run Dutch windows or English windows, meaning that I can’t filter on words, because those hotfixes and the words will be different on every computer. Anybody have a nice sollution to this problem.

Note: I have seen it solved the other way around, leaving only the relevant info using findstr. But, because that depends on the language, it is not a viable option.

Edit: The hotfixes are named differently on different OS’es as well, meaning that I can’t filter on those. Example: on the XP SP3 I tested, most of the list will be compromised of hotfixes called “[##]file1” on vista however, you will see hex values in the list.

Answer 1

EDIT

My original answer did not work, but I have another idea that works as long as the number and order of each systeminfo header is consistent. I am relying on the fact that the Hotfix(s): is always the 31st header.

@echo off
setlocal enableDelayedExpansion
>systemInfo.txt (
  set cnt=0
  for /f "delims=" %%A in ('systeminfo') do (
    set "ln=%%A"
    if "!ln:~0,1!"==" " (if !cnt! neq 31 echo !ln!) else (
      echo !ln!
      set /a cnt+=1
    )
  )
  ipconfig
)

If the number and/or order of the headers can change, then I don’t see how there can be a solution, other then to bite the bullet and look for the specific header text, accounting for all languages that you need to support.

Original failed answer

I don’t know how reliable this is. It works for me on my machine, but it would not surprise me if on some machines it strips things it shouldn’t.

>systemInfo.txt (
  systeminfo|findstr /vxrc:"                           \[[0-9]*\]: [^ ]*"
  ipconfig
)

All my hotfixes begin with KB, followed by a string of numbers. If this is always true, then the above could be improved as:

>systemInfo.txt (
  systeminfo|findstr /vxrc:"                           \[[0-9]*\]: KB[0-9]*"
  ipconfig
)