Question

I am defining this function in one of my classes:

public function onUse():void {};

Then in another of my classes (let’s call it “class2”), I create a object of this class, and then want to override this function with another one. After some Google-Fu, I have found this, and used it…

button.onUse {
    variable = value;
}

…but it executes instantly, and not when onUse() is called – which seems to be an empty function, always.

I didn’t find anything more than that – I tried a few things myself, like specifying a function inside class2 and using button.onUse = function();, but it always throws errors.

Can anyone tell me whether what I am trying to do is actually possible, and if it is, how can I do it?

Answer 1

You can only override functions when you are extending the class:

public class A {
    public function foo():void {
        doStuff();
    }
}

public class B extends A {
    override public function foo():void {
        doOtherStuff();
    }
}

var n:A = new A(); 
n.foo(); // => calls doStuff();

var o:B = new B();
o.foo(); // => calls doOtherStuff();

Hence, assigning a different function to a class method of an instance is not possible at runtime.

You can, however, let your original class contain a field of type Function, and then simply assign a different closure to it.

public class A {
    public var foo:Function;
}

var n:A = new A();
n.foo = function ():void { 
    doStuff();
};
n.foo(); // => calls doStuff();

var o:A = new A();
o.foo = function ():void {
    doOtherStuff();
}
o.foo(); // => calls doOtherStuff();