Question

I am doing a pipeline delimited report using perl. How do i include the delimiting character | between the fields. | symbol in perl stands for aligning the field to centre.

format details =
@<<<<<<<<<<<<  @<<<<<<<<<<<<<<<<<<<<<<<  @<<<<<<<<<<<<
"$rtype", "$rdescr", "$rid"

OUTFILE->format_name("details");
write OUTFILE;

Answer 1

If you’re using that format, then you could as simply use:

print OUTFILE "$rtype|$rdescr|$rid\n";

You should think about migrating to lexical file handles though ISTR that formats require the non-lexical handles. However, that doesn’t automatically truncate the fields to length, which may matter to you.

This code works for me:

#!/usr/bin/env perl
use strict;
use warnings;

open OUTFILE, ">", "file.out" or die "A horrible death";

my $rtype = "ABCDEFG HIJKLMN OPQRST";
my $rdescr = "Abc def ghi jkl mno pqr stuv wxyz?";
my $rid   = "0123456789";

format details =
@<<<<<<<<<<<< | @<<<<<<<<<<<<<<<<<<<<<<< | @<<<<<<<<<<<< |
"$rtype", "$rdescr", "$rid"
.

OUTFILE->format_name("details");
write OUTFILE;


$rtype = "ABCDEFG";
$rdescr = "Abc def";
$rid   = "01234";
write OUTFILE;

The output it produces (in file.out) is:

ABCDEFG HIJKL | Abc def ghi jkl mno pqr  | 0123456789    |
ABCDEFG       | Abc def                  | 01234         |

(PS: I tried \| first; it produced \| in the output, so it was an easy and reasonable inference that the backslash was not actually needed.)

With lexical file handle:

#!/usr/bin/env perl
use strict;
use warnings;

open my $out, ">", "file.out" or die "A horrible death";

my $rtype = "ABCDEFG HIJKLMN OPQRST";
my $rdescr = "Abc def ghi jkl mno pqr stuv wxyz?";
my $rid   = "0123456789";

format details =
@<<<<<<<<<<<< | @<<<<<<<<<<<<<<<<<<<<<<< | @<<<<<<<<<<<< |
"$rtype", "$rdescr", "$rid"
.

$out->format_name("details");
write $out;


$rtype = "ABCDEFG";
$rdescr = "Abc def";
$rid   = "01234";
write $out;

This gives the same output.