Question

I am getting errors while looping through a dictionary trying to go to specified cells as the dictionary contains column addresses. Here is a little backround-

1. Loop through any cells that have a comment (top row only!!)
2. Store that column and comment text in a dictionary object
3. Loop through the remaining rows and ONLY go to the cells in the same column as the comment from the first row. This information will then be sent to another worksheet

E.g.,

|CELL1|CELL2 (W COMMENT)|CELL3|

–Store Cell2 column address which would be 2 and the comment, select the next cell down at column position 2.

I have posted my whole class but the part you need to pay attention to is at the very bottom with the commented code. I realize it is probably a bit hefty for code so if you see some shortcuts please advise!

Option Explicit
Public buildWs As Worksheet
Public targWs As Worksheet
Public CommentVal As Comment
Public FirstRow As Range
Public targLastrow As Range
Public firstRecordRow As Range
Public commRange As Range
Public commCell As Range
Public recordRow As Range
Public LastRow As Long
Public vertRange As Range
Public vertCell As Range

'//---------------------------------------
'//getter and setter methods of the class
Public Property Get ItemNum() As Comment
    ItemNum = CommentVal
End Property
Public Property Let ItemNum(Value As Comment)
    CommentVal = ItemNum
End Property

Public Property Get Start() As Range
    Start = FirstRow
End Property
Public Property Let Start(Value As Range)
    Set FirstRow = Value
End Property

Public Property Get affBuild() As Worksheet
    affBuild = buildWs
End Property
Public Property Let affBuild(Value As Worksheet)
    Set buildWs = Value
End Property

Public Property Get allinaBuid() As Worksheet
    allinaBuild = targWs
End Property
Public Property Let allinaBuild(Value As Worksheet)
    Set targWs = allinaBuild
End Property

Public Sub setId()
    Dim rowCount As Integer
    Dim element As Variant
    Dim n As Integer
    Dim z As Integer
    Dim keyValue As New Dictionary
    Dim col As String

    On Error Resume Next
    Set commRange = buildWs.Cells _
      .SpecialCells(xlCellTypeComments)
    On Error GoTo 0
    If commRange Is Nothing Then
        MsgBox "No Comments Found"
        Exit Sub
    End If
    buildWs.Activate
    For Each commCell In commRange
        commCell.Select
        '// do something here with the cell since it meets our criteria of having a comment
        keyValue.Add ActiveCell.Column, ActiveCell.Comment.Text
    Next commCell
    '// loop through the vertical range for the 1st column to get a count of rows
    '//--------------------------------------------------------------------------
    Set vertRange = Range("A:A")
    vertRange.Select
    For Each vertCell In vertRange
        If ActiveCell.Value = "" Then
            Exit For
        Else
            rowCount = rowCount + 1
            ActiveCell.Offset(1, 0).Select
        End If
    Next vertCell
    '// row count is off by one since we don't care about the first row
    rowCount = rowCount - 1

    '// select the first real row we care about as row1 is only header info
    FirstRow.Select
    For Each element In keyValue
        col = element
        MsgBox col '<-- this displays the correct dictionary information -->
        Cells("2", col).Select '<-- this fails and gives me an error! -->
    Next element
End Sub

Answer 1

The error occurs because you need to pass integer numbers to Cells("2", col), not strings. You should either pass a Variant containing a Long or a Long.

Dim col As Variant

or

Dim col As Long

Then

Cells(2, col).Select

---

You also have an error here

Public Property Let allinaBuild(Value As Worksheet)
    Set targWs = Value ' <== was   Set targWs = allinaBuild
End Property

(I replaced allinaBuild by Value)

Same error in Let ItemNum