Question

I am having problems getting the desired result in cmd batch file. I need to print the result in the below mentioned format

@echo off
setlocal enabledelayedexpansion
for %%i in (8 7 6 5 4 3 2) do (

echo %%i
if %%i EQU 8 goto lvl8
if %%i EQU 3 goto lvl35
if %%i EQU 2 (goto lvl3) else goto lvls

:lvl8
set str1=8
set str2=16

:lvl35
set str1=3.5
set str2=4

:lvl3
set str1=3
set str2=3.5

:lvls
set str1=%%i

set /A str2=%%i+1

echo %%i
rem echo.!str!
echo.!str1!
echo.!str2!
)
endlocal

Expected outputs

8
8
16
7
7
8
6
6
7
5
5
6
4
4
5
3
3.5
4
2
3
3.5

Right now am getting the following:

8
Missing operand
%i

%i
3.5

EDIT: updated the above question as per Joey’s solution.

Answer 1

%i% has no value. Were you intending to use %%i?

To clarify, what cmd sees here:

if  EQU 8 goto lvl8
if  EQU 3 goto lvl35
if  EQU 2 (goto lvl3) else goto lvls

which clearly is a syntax error.

---

Ok, after your edit, there are a few problems, still. If you use goto you apparently leave the for loop. Thus, after a goto %%i doesn’t have a value, either and the loop only runs once.

Then there is the way you use the gotos; a goto is a jump to a specific line in code. Program flow continues normally after that and thus if you jump to lvl8 you end up running all subsequent lines, too, even those after :lvl35 and :lvl3 or :lvls. After each section you jump to you’d have to include an explicit jump to the end of the loop to skip the unwanted lines. But that’s semi-beside the point, as you cannot use goto within the for loop, as mentioned above.

So the first thing you should do is get rid of goto and instead use structured programming. if can accept a block, too. Then you output %%i once too often, which can easily be corrected, too.

It now looks like this here:

@echo off
setlocal enabledelayedexpansion
for %%i in (8 7 6 5 4 3 2) do (
    echo %%i

    if %%i EQU 8 (
        set str1=8
        set str2=16
    ) else if %%i EQU 3 (
        set str1=3.5
        set str2=4
    ) else if %%i EQU 2 (
        set str1=3
        set str2=3.5
    ) else (
        set str1=%%i
        set /A str2=%%i+1
    )

    rem echo %%i
    rem echo.!str!
    echo.!str1!
    echo.!str2!
)
endlocal

Note that each if also has an else to avoid running the last else for all numbers except 2. The output is now correct. Code can be found in my SVN repository, too.