Question

I am having the following issue :

I have a table which looks like this :

WEIGHT    DATE  8/1/11    1/1/11   5/1/11 ... 10/25/11 
NAME   CLASS
NICK     1        A          .        A       .
JOHN     1       c+         C-        .        B-
JOHN     2        A          .        .        .
MIKE     2       B           B        B+        A
BOB      3       D           C        C         .
...

The dates are random dates, and they are not ordered .

I would like to order my dates (my columns) in sas. I looked up some things on google but there is nothing for this particular problem, since I have 300 dates, and therefore 300 columns names.

For you information :

My data originally looked like this :

calendar1 :

NAME CLASS CALENDaRDATE GPA
JOHN  1      1/1/11      C-
JOHN  1      8/1/11      C+
...

And I used this proc to create my table :

    proc sort data=calendar1;
        by  NAME ClASS CALENDARDATE;
    run;

    PROC TRANSPOSE DATA = calendar1 OUT = calendar2 ;
       BY nAME cLASS; 
       VAR GPA;
       ID CALeNdaRDATE; 
    RUN ; 

Do you have an Idea on how to sort my columns by dates ?

Answer 1

This is a not-so-elegant solution for your reference (some are borrowed from CarolinaJay65’s input). You can reorder the column using RETAIN statement.

I don’t think you can keep column name like ‘5/1/11’ since SAS doesn’t allow “/” in column name. Also the first character can’t be numerical.

data work.calendar1 (drop=dt);
 input name $ class $ dt $ gpa $;
 calendardate=mdy(scan(dt,1),scan(dt,2),scan(dt,3)); 
  format calendardate mmddyy10.;
datalines;
 JOHN  1      1/1/11      C-
 JOHN  1      8/1/11      C+
 JOHN  1      10/25/11    B-
 JOHN  2      8/1/11      A
 NICK  1      8/1/11      A
 NICK  1      5/1/11      A
 MIKE  2      8/1/11      B
 MIKE  2      1/1/11      B
 MIKE  2      5/1/11      B+
 MIKE  2      10/25/11    B
 BOB   3      10/25/11     D
 BOB   3      1/1/11      C
 BOB   3      5/1/11      C
 ;

proc sort data=work.calendar1;
 by  NAME ClASS CALENDARDATE;
run;

PROC TRANSPOSE DATA = calendar1 OUT = calendar2(drop=_name_) ;
 BY nAME cLASS; 
 VAR GPA;
 ID CALeNdaRDATE; 
RUN ; 

proc sort data=calendar1(keep=CALENDARDATE) out=datecol nodupkey;
by CALENDARDATE;
run;

data datecol;
set datecol;
format col $11.;
col=cats('_',tranwrd(put(CALENDARDATE,mmddyy10.),'/','_'));
run;

proc sql;
select col into :x separated by ' ' from datecol;
quit;

data calendar2;
retain name class &x;
set calendar2;
run;