Question

I am looking for a VBA user-defined function that will read in the contents of a .csv file and return the results as an array to populate the cells of a worksheet, i.e something like this:

   =CSV_Read("path/to/file.csv")

I have found this but looks proprietary/shareware. Does anyone know of any alternatives? Or what the best approach to rolling my own in VBA would be?

Answer 1

In your VBA code, add reference to “Microsoft Scripting Runtime”.
Add a module, paste the following code.

Option Explicit
Public Function CSV_Read(ByVal path As String) As Variant
Dim fso As Scripting.FileSystemObject
Dim tsm As Scripting.TextStream

Dim data

Dim text As String
Dim allRowsInArray As Variant
Dim currentLineToArray As Variant

Dim columnCount As Integer
Dim columnCounter As Integer

Dim rowCounter As Integer
Dim rowCount As Integer

Set fso = New Scripting.FileSystemObject
Set tsm = fso.OpenTextFile(path, ForReading)

rowCounter = 0
If Not tsm.AtEndOfStream Then
    text = tsm.ReadAll

    tsm.Close
    Set tsm = Nothing
    Set fso = Nothing

    allRowsInArray = Split(text, vbCrLf)
    rowCount = UBound(allRowsInArray)

    Do While rowCounter < (rowCount + 1)
        currentLineToArray = Split(allRowsInArray(rowCounter), ",")

        If Not IsArray(data) Then
            columnCount = UBound(currentLineToArray)
            ReDim data(rowCount, columnCount)
        End If

        For columnCounter = 0 To columnCount
            data(rowCounter, columnCounter) = currentLineToArray(columnCounter)
        Next

        rowCounter = rowCounter + 1
    Loop
End If

CSV_Read = data
End Function

Sample CSV file data

a,b,c,d,e,f,g
1,2,3,4,5,6,7
7,6,5,4,3,2,1
q,w,e,r,t,y,u

Looking at the data, it has 7 columns and 4 rows.

Now, goto cell A1 and select the range from cell A1 to G4.
Type in the formula (=CSV_Read("the full path to your csv file"), in cell A1 (keeping the selection as it is).

Important:
Press CTRL + SHIFT + ENTER, once you have finished typing in the formula. This is array formula.