Question

I am making a display file with a single selection list created by a single page subfile. With this implementation I found two problems.

The first one is that when I pressed Enter to select an option for the first time when the display file had been loaded, the READC operation in the RPGLE would return the correct value (it returns the character string in the subfile record). When I pressed Enter again with a different option selected, the value from the previous Enter press was returned. In subsequent turns it kept returning the value of the selection just before it. I added a second READC after the first one in the program just to see what would happen, and found out that both READC returned values. The first one returned the value from the previous selection, the second returned the value I had currently selected.

The second problem is that selecting the same option for multiple times did not work, i.e. it only worked for the first time and if I tried to select it again immediately it did not respond.

I had applied the same logic to another single selection list made of load all subfile and it did not have any of these problems. Does it mean that single page subfile is not suitable for making single selection list?

Here is the DDS for the subfile:

A                R ITFMAT02
A                  S1OPTN          50 A 6 11
A                R ITFMAT01
A                                           SFLCLT(ITFMAT02)
A 27                                        SFLDSP
A 28                                        SFLCLR
A 29                                        SFLEND
A                                           CF12(12)
A                                           SFLSNGCHC(*AUTOSLT)

Here is the RPGLE main loop:

C        *IN12     DOWEQ       *OFF
C                  EXFMT       ITFMAT01
C        *IN12     IFEQ        *ON
C                  LEAVE
C                  ENDIF
C                  READC       ITFMAT02
C                  MOVEL       S0OPTN         W1OPTN
                     .
                     .
                     .
C                  ENDDO                     

Answer 1

Here is a working example. I suspect you haven’t been clearing the choice control field.

 A*
 A          R ITFMAT02                  SFL
 A            CTL            1Y 0H      SFLCHCCTL
 A            S1OPTN        50A     6 11
 A*
 A          R ITFMAT01
 A                                      SFLCTL(ITFMAT02)
 A  27                                  SFLDSP
 A N28                                  SFLDSPCTL
 A  28                                  SFLCLR
 A  29                                  SFLEND
 A                                      SFLSIZ(15)
 A                                      SFLPAG(05)
 A                                      CF12(12)
 A                                      SFLSNGCHC(*AUTOSLT)
 A            SFLRRN         4S 0H      SFLRCDNBR(CURSOR)
 A                                  1 30'Title'
 A            CHOICE         4S 0   3  1
 A                                  4  5'Choose one'

And the RPG. I don’t normally work in fixed format but tried to mirror the existing style.

 fsotest    cf   e             workstn
 f                                     SFILE(itfmat02:RRN)

 c* clear sfl
 c                   z-add     1             sflrrn
 c                   setoff                                       272829
 c                   seton                                        28
 c                   write     itfmat01
 c                   setoff                                       28
 c* load sfl
 c     1             do        9             rrn               4 0
 c                   movel     rrn           s1optn
 c                   write     itfmat02
 c                   seton                                        27
 c                   enddo

 C     *IN12         DOWEQ     *OFF
 C                   EXFMT     ITFMAT01

 C     *IN12         IFEQ      *ON
 C                   LEAVE
 C                   ENDIF

 C                   READC     ITFMAT02                               80
 C  n80              do
 C                   movel     rrn           choice
 C                   z-add     0             ctl
 C                   update    itfmat02
 C                   enddo
 C                   ENDDO

 c                   seton                                        lr